X-Git-Url: https://git.rrq.au/?a=blobdiff_plain;f=main.asm;h=407d3a30a9baad7bbd6b05b9818d50d29cf889b6;hb=d8a61fe84d4b71c21c4ce18a9b7bc78000db725a;hp=a4db7329bb1f8ed39570b1196f0df2556f75e761;hpb=f0df53c35124c9a5e2b045aba60b513faa344567;p=rrq%2Fjonasforth.git

diff --git a/main.asm b/main.asm
index a4db732..407d3a3 100644
--- a/main.asm
+++ b/main.asm
@@ -1,34 +1,25 @@
 ;; vim: syntax=fasm
 
-format ELF64 executable
-
-;; "Syscalls" {{{
-
-;; [NOTE] Volatile registers Linux (syscalls) vs UEFI
+;; At compile-time we load the module given by the environment variable
+;; OS_INCLUDE. This module should define the following macros:
 ;;
-;;   Linux syscalls: RAX, RCX, R11
-;;   UEFI:           RAX, RCX, R11, RDX, R8, R9, R10
-
-;; We are in the process of replacing our dependency on Linux with a dependency
-;; on UEFI. The following macros attempt to isolate what would be syscalls in
-;; Linux; thus, we will be able to replace these with UEFI-based implementations,
-;; and in theory we should expect the program to work.
-
-;; Print a string of a given length.
+;; Each of these functions should preserve the value of RSI and RSP. They may
+;; use other registers as they like.
 ;;
-;; Input:
-;; - RCX = Pointer to buffer
-;; - RDX = Buffer length
+;; os_initialize
+;;   Called at initialization.
 ;;
-;; Clobbers: RAX, RCX, R11, RDI, RSI
-macro sys_print_string {
-  mov rax, 1
-  mov rdi, 1
-  mov rsi, rcx
-  syscall
-}
-
-;; }}}
+;; os_print_string
+;;   Takes a string buffer in RCX and the length in RDX, and prints the string
+;;   to the console.
+;;
+;; os_read_char
+;;   Wait for the user to type a key, and then put the corresponding ASCII byte
+;;   into RAX.
+;;
+;; os_terminate
+;;   Shut down the system, returning the error code given in RAX.
+include '%OS_INCLUDE%'
 
 ;; The code in this macro is placed at the end of each Forth word. When we are
 ;; executing a definition, this code is what causes execution to resume at the
@@ -87,9 +78,7 @@ macro forth_asm label, name, immediate {
 .start:
 }
 
-segment readable executable
-
-entry main
+section '.text' code readable executable
 
 include "impl.asm"      ; Misc. subroutines
 include "bootstrap.asm" ; Forth words encoded in Assembly
@@ -98,6 +87,8 @@ main:
   cld                        ; Clear direction flag so LODSQ does the right thing.
   mov rbp, return_stack_top  ; Initialize return stack
 
+  call os_initialize
+
   mov rax, MAIN
   jmp qword [rax]
 
@@ -124,6 +115,17 @@ forth_asm LIT, 'LIT'
   push rax
   next
 
+;; When LITSTRING is encountered while executing a word, it instead reads a
+;; string from the definition of that word, and places that string on the stack
+;; as (buffer, length).
+forth_asm LITSTRING, 'LITSTRING'
+  lodsb
+  push rsi ; Buffer
+  movzx rax, al
+  push rax ; Length
+  add rsi, rax ; Skip over string before resuming execution
+  next
+
 ;; Given a string (a pointer following by a size), return the location of the
 ;; dictionary entry for that word. If no such word exists, return 0.
 forth_asm FIND, 'FIND'
@@ -188,42 +190,79 @@ forth_asm EMIT, 'EMIT'
 
   lea rcx, [rsp]
   mov rdx, 1
-  sys_print_string
+  call os_print_string
 
   add rsp, 8
   popr rax
   popr rsi
   next
 
-;; Read a word from standard input and push it onto the stack as a pointer and a
-;; size. The pointer is valid until the next call to READ_WORD.
-forth_asm READ_WORD, 'READ-WORD'
-  mov [.rsi], rsi
+;; Read a single character from the current input stream. Usually, this will wait
+;; for the user to press a key, and then return the corresponding character. When
+;; reading from a special buffer, it will instead return the next characater from
+;; that buffer.
+;;
+;; The ASCII character code is placed on the stack.
+forth_asm KEY, 'KEY'
+  call .impl
+  push rax
+  next
 
-  call read_word
-  push rdi                      ; Buffer
-  push rdx                      ; Length
+;; Result in RAX
+.impl:
+  ;; Are we reading from user input or from the input buffer?
+  cmp [input_buffer], 0
+  jne .from_buffer
 
-  mov rsi, [.rsi]
-  next
+  ;; Reading user input
+  call os_read_char
+  ret
 
-;; Read a word from a buffer. Expects (buffer buffer-length) on the stack.
-;; Updates buffer and buffer-length, such that the word has been removed from
-;; the buffer. Appends (word-buffer word-buffer-length) to the stack.
-forth_asm POP_WORD, 'POP-WORD'
-  pushr rsi
+.from_buffer:
+  ;; Reading from buffer
+  mov rax, [input_buffer]
+  movzx rax, byte [rax]
+
+  inc [input_buffer]
+  dec [input_buffer_length]
+  ret
 
-  pop rcx ; Length
-  pop rsi ; Buffer
+;; Read a word and push it onto the stack as a pointer and a size. The pointer
+;; is valid until the next call to READ_WORD.
+forth_asm READ_WORD, 'READ-WORD'
+  push rsi
+.skip_whitespace:
+  ;; Read characters until one of them is not whitespace.
+  call KEY.impl
+  ;; We consider newlines and spaces to be whitespace.
+  cmp al, ' '
+  je .skip_whitespace
+  cmp al, $A
+  je .skip_whitespace
+
+  ;; We got a character that wasn't whitespace. Now read the actual word.
+  mov [.length], 0
 
-  call pop_word
+.read_alpha:
+  movzx rbx, [.length]
+  mov rsi, .buffer
+  add rsi, rbx
+  mov [rsi], al
+  inc [.length]
 
-  push rsi ; Updated buffer
-  push rcx ; Length of updated buffer
-  push rdi ; Word buffer
-  push rdx ; Length of word buffer
+  call KEY.impl
+
+  cmp al, ' '
+  je .end
+  cmp al, $A
+  jne .read_alpha
+
+.end:
+  pop rsi
+  push .buffer
+  movzx rax, [.length]
+  push rax
 
-  popr rsi
   next
 
 ;; Takes a string on the stack and replaces it with the decimal number that the
@@ -247,7 +286,7 @@ forth_asm TELL, 'TELL'
 
   pop rdx ; Length
   pop rcx ; Buffer
-  sys_print_string
+  call os_print_string
 
   popr rsi
   popr rax
@@ -255,9 +294,8 @@ forth_asm TELL, 'TELL'
 
 ;; Exit the program cleanly.
 forth_asm TERMINATE, 'TERMINATE'
-  mov rax, $3C
-  mov rdi, 0
-  syscall
+  mov rax, 0
+  call os_terminate
 
 ;; Duplicate a pair of elements.
 forth_asm PAIRDUP, '2DUP'
@@ -346,7 +384,7 @@ forth_asm DOTU, '.U'
   ;; Print the buffer
   mov rcx, .buffer
   mov rdx, [.printed_length]
-  sys_print_string
+  call os_print_string
 
   ;; Restore RSI and continue execution
   pop rsi
@@ -406,25 +444,20 @@ forth_asm TIMESMOD, '/MOD'
   push rdx                      ; a % b
   next
 
-;; Read user input until next " character is found. Push a string containing the
+;; Read input until next " character is found. Push a string containing the
 ;; input on the stack as (buffer length). Note that the buffer is only valid
 ;; until the next call to S" and that no more than 255 characters can be read.
-;;
-;; [TODO] We want to be able to use this when reading from buffers (e.g. in
-;; INTERPRET-STRING) too!
 forth_asm READ_STRING, 'S"'
+  ;; If the input buffer is set, we should read from there instead.
+  cmp [input_buffer], 0
+  jne read_string_buffer
+
   push rsi
 
   mov [.length], 0
 
 .read_char:
-  mov rax, 0
-  mov rdi, 0
-  mov rsi, .char_buffer
-  mov rdx, 1
-  syscall
-
-  mov al, [.char_buffer]
+  call os_read_char
   cmp al, '"'
   je .done
 
@@ -442,19 +475,12 @@ forth_asm READ_STRING, 'S"'
 
   next
 
-;; BUF" works a bit like S, but it reads the string from the current input
-;; buffer described in INPUT-BUFFER and INPUT-LENGTH. We use this fucntion in
-;; sys.f to store strings.
-forth_asm BUF_READ_STRING, 'BUF"'
+read_string_buffer:
   push rsi
 
   ;; We borrow READ_STRING's buffer. They won't mind.
   mov [READ_STRING.length], 0
 
-  ;; Skip space ([TODO]: Shouldn't we do this while parsing instead?)
-  inc [input_buffer]
-  dec [input_buffer_length]
-
 .read_char:
   mov rbx, [input_buffer]
   mov al, [rbx]
@@ -583,7 +609,7 @@ forth INPUT_LENGTH, 'INPUT-LENGTH'
   dq LIT, input_buffer_length
   dq EXIT
 
-segment readable writable
+section '.data' readable writable
 
 ;; The LATEST variable holds a pointer to the word that was last added to the
 ;; dictionary. This pointer is updated as new words are added, and its value is
@@ -594,6 +620,12 @@ latest_entry dq initial_latest_entry
 ;; it is compiling.
 var_STATE dq 0
 
+;; The interpreter can read either from standard input or from a buffer. When
+;; input-buffer is set (non-null), words like READ-WORD and S" will use this
+;; buffer instead of reading user input.
+input_buffer dq 0
+input_buffer_length dq 0
+
 FIND.rsi dq ?
 
 READ_WORD.rsi dq ?
@@ -609,22 +641,19 @@ DOTU.rbuffer rq 16
 DOTU.length dq ?
 DOTU.printed_length dq ?
 
+KEY.buffer dq ?
+
+READ_WORD.buffer rb $FF
+READ_WORD.length db ?
+
 ;; Reserve space for compiled words, accessed through HERE.
 here dq here_top
 here_top rq $4000
 
-;; Pointer to input buffer and its length. Used as local variable in
-;; INTERPRET-STRING (see bootstrap.asm). [TODO] The code organization is a bit
-;; awkward here.
-input_buffer dq ?
-input_buffer_length dq ?
-
 ;; Return stack
 rq $2000
 return_stack_top:
 
-segment readable
-
 ;; We store some Forth code in sys.f that defined common words that the user
 ;; would expect to have available at startup. To execute these words, we just
 ;; include the file directly in the binary, and then interpret it at startup.