X-Git-Url: https://git.rrq.au/?a=blobdiff_plain;f=main.asm;h=28cd430df50123520fb322304c3c765e84d788d6;hb=393bd34286ed22c677fbbc70c5a3e70aa655c09f;hp=f466a104d0b7caaba7e2f9f5f7ddfcf284a53e23;hpb=38ab2f16dd683ac65c0567f3d7a079dcdc3edf2f;p=rrq%2Fjonasforth.git

diff --git a/main.asm b/main.asm
index f466a10..28cd430 100644
--- a/main.asm
+++ b/main.asm
@@ -23,14 +23,50 @@ macro popr x {
   add rbp, 8
 }
 
+;; The following macro generates the dictionary header. It updates the
+;; initial_latest_entry variable, which is used as the initial value of the
+;; latest_entry variable that is made available at runtime.
+;;
+;; The header contains a link to the previous entry, the length of the name of
+;; the word and the word itself as a string literal.
+;;
+;; This macro also defines a label LABEL_entry.
+initial_latest_entry = 0
+macro header label, name {
+  local .string_end
+
+label#_entry:
+  dq initial_latest_entry
+  db .string_end - ($ + 1)
+  db name
+  .string_end:
+label:
+
+initial_latest_entry = label#_entry
+}
+
+;; Define a Forth word that is implemented in assembly. See 'header' for details.
+macro forth_asm label, name {
+  header label, name
+  dq .start
+.start:
+}
+
+;; Define a Forth word that is implemented in Forth. (The body will be a list of
+;; 'dq' statements.)
+macro forth label, name {
+  header label, name
+  dq docol
+}
+
 segment readable executable
 
 main:
   cld                        ; Clear direction flag so LODSQ does the right thing.
   mov rbp, return_stack_top  ; Initialize return stack
 
-  mov rsi, program
-  next
+  mov rax, MAIN
+  jmp qword [rax]
 
 program: dq MAIN
 
@@ -44,33 +80,76 @@ docol:
 
 ;; This word is called at the end of a Forth definition. It just needs to
 ;; restore the old value of RSI (saved by 'docol') and resume execution.
-EXIT:
-  dq .start
-.start:
+forth_asm EXIT, 'EXIT'
   popr rsi
   next
 
 ;; LIT is a special word that reads the next "word pointer" and causes it to be
 ;; placed on the stack rather than executed.
-LIT:
-  dq .start
-.start:
+forth_asm LIT, 'LIT'
   lodsq
   push rax
   next
 
+;; Given a string (a pointer following by a size), return the location of the
+;; dictionary entry for that word. If no such word exists, return 0.
+forth_asm FIND, 'FIND'
+  mov [.rsi], rsi
+  pop [.search_length]
+  pop [.search_buffer]
+
+  ;; RSI contains the entry we are currently looking at
+  mov rsi, [latest_entry]       ; Start with the last added word
+
+.loop:
+  movzx rcx, byte [rsi + 8]     ; Length of word being looked at
+  cmp rcx, [.search_length]
+  jne .next    ; If the words don't have the same length, we have the wrong word
+
+  ;; Otherwise, we need to compare strings
+  lea rdx, [rsi + 8 + 1]        ; Location of character being compared in entry
+  mov rdi, [.search_buffer]     ; Location of character being compared in search buffer
+.compare_char:
+  mov al, [rdx]
+  mov ah, [rdi]
+  cmp al, ah
+  jne .next                     ; They don't match; try again
+  inc rdx                       ; These characters match; look at the next ones
+  inc rdi
+  loop .compare_char
+
+  jmp .found                    ; They match! We are done.
+
+.next:
+  mov rsi, [rsi]                ; Look at the previous entry
+  cmp rsi, 0
+  jnz .loop                    ; If there is no previous word, exit and return 0
+
+.found:
+  push rsi
+
+  mov rsi, [.rsi]
+  next
+
+;; Given an entry in the dictionary, return a pointer to the codeword of that
+;; entry.
+forth_asm TCFA, '>CFA'
+  pop rax
+  add rax, 8                    ; [rax] = length of name
+  movzx rbx, byte [rax]
+  inc rax
+  add rax, rbx                  ; [rax] = codeword
+  push rax
+  next
+
 ;; BRANCH is the fundamental mechanism for branching. BRANCH reads the next word
 ;; as a signed integer literal and jumps by that offset.
-BRANCH:
-  dq .start
-.start:
+forth_asm BRANCH, 'BRANCH'
   add rsi, [rsi] ; [RSI], which is the next word, contains the offset; we add this to the instruction pointer.
   next           ; Then, we can just continue execution as normal
 
 ;; 0BRANCH is like BRANCH, but it jumps only if the top of the stack is zero.
-ZBRANCH:
-  dq .start
-.start:
+forth_asm ZBRANCH, '0BRANCH'
   ;; Compare top of stack to see if we should branch
   pop rax
   cmp rax, 0
@@ -81,10 +160,18 @@ ZBRANCH:
   add rsi, 8     ; We need to skip over the next word, which contains the offset.
   next
 
+;; Duplicate the top of the stack.
+forth_asm DUP_, 'DUP'
+  push qword [rsp]
+  next
+
+;; Execute the codeword at the given address.
+forth_asm EXEC, 'EXEC'
+  pop rax
+  jmp qword [rax]
+
 ;; Expects a character on the stack and prints it to standard output.
-EMIT:
-  dq .start
-.start:
+forth_asm EMIT, 'EMIT'
   pushr rsi
   pushr rax
   mov rax, 1
@@ -98,17 +185,20 @@ EMIT:
   next
 
 ;; Prints a newline to standard output.
-NEWLINE:
-  dq docol
+forth NEWLINE, 'NEWLINE'
   dq LIT, $A
   dq EMIT
   dq EXIT
 
+;; Prints a space to standard output.
+forth SPACE, 'SPACE'
+  dq LIT, ' '
+  dq EMIT
+  dq EXIT
+
 ;; Read a word from standard input and push it onto the stack as a pointer and a
 ;; size. The pointer is valid until the next call to READ_WORD.
-READ_WORD:
-  dq .start
-.start:
+forth_asm READ_WORD, 'READ-WORD'
   mov [.rsi], rsi
   mov [.rax], rax
 
@@ -160,9 +250,7 @@ READ_WORD:
 
 ;; Takes a string on the stack and replaces it with the decimal number that the
 ;; string represents.
-PARSE_NUMBER:
-  dq .start
-.start:
+forth_asm PARSE_NUMBER, 'PARSE-NUMBER'
   pop [.length]                 ; Length
   pop rdi                       ; String pointer
   mov r8, 0                     ; Result
@@ -206,17 +294,14 @@ PARSE_NUMBER:
 
   next
 
-READ_NUMBER:
-  dq docol
+forth READ_NUMBER, 'READ-NUMBER'
   dq READ_WORD
   dq PARSE_NUMBER
   dq EXIT
 
 ;; Takes a string (in the form of a pointer and a length on the stack) and
 ;; prints it to standard output.
-TELL:
-  dq .start
-.start:
+forth_asm TELL, 'TELL'
   mov rbx, rsi
   mov rcx, rax
 
@@ -231,32 +316,12 @@ TELL:
   next
 
 ;; Exit the program cleanly.
-TERMINATE:
-  dq .start
-.start:
+forth_asm TERMINATE, 'TERMINATE'
   mov rax, $3C
   mov rdi, 0
   syscall
 
-PUSH_HELLO_CHARS:
-  dq docol
-  dq LIT, $A
-  dq LIT, 'o'
-  dq LIT, 'l'
-  dq LIT, 'l'
-  dq LIT, 'e'
-  dq LIT, 'H'
-  dq EXIT
-
-PUSH_YOU_TYPED:
-  dq .start
-.start:
-  push you_typed_string
-  push you_typed_string.length
-  next
-
-HELLO:
-  dq docol
+forth HELLO, 'HELLO'
   dq LIT, 'H', EMIT
   dq LIT, 'e', EMIT
   dq LIT, 'l', EMIT
@@ -267,9 +332,7 @@ HELLO:
   dq EXIT
 
 ;; .U prints the value on the stack as an unsigned integer in hexadecimal.
-DOTU:
-  dq .start
-.start:
+forth_asm DOTU, '.U'
   mov [.length], 0
   mov [.printed_length], 1
   pop rax                       ; RAX = value to print
@@ -329,18 +392,33 @@ DOTU:
   pop rsi
   next
 
-MAIN:
-  dq docol
+forth MAIN, 'MAIN'
   dq HELLO
-  dq READ_NUMBER, DOTU, NEWLINE
-  dq BRANCH, -8 * 4
+  dq READ_WORD, FIND, TCFA, EXEC
+  dq BRANCH, -8 * 5
   dq TERMINATE
 
 segment readable writable
 
+latest_entry dq initial_latest_entry
+
+SPACE_string db 'SPACE'
+.length = $ - SPACE_string
+HELLO_string db 'HELLO'
+.length = $ - HELLO_string
+DOTU_string db '.U'
+.length = $ - DOTU_string
+HELLA_string db 'HELLA'
+.length = $ - HELLA_string
+
+
 you_typed_string db 'You typed: '
 .length = $ - you_typed_string
 
+FIND.search_length dq ?
+FIND.search_buffer dq ?
+FIND.rsi dq ?
+
 READ_WORD.rsi dq ?
 READ_WORD.rax dq ?
 READ_WORD.max_size = $FF