X-Git-Url: https://git.rrq.au/?a=blobdiff_plain;f=main.asm;h=1a41bb9a2c1dc30f1050200a9e724a56885eff47;hb=a6faff31f03d96b6a62188f330848004119d5165;hp=8af0955347ffb2f088ff8b65cc8bb531f4065649;hpb=06d7dcb24315373eebf8f1e8082bb39e33b3fcad;p=rrq%2Fjonasforth.git

diff --git a/main.asm b/main.asm
index 8af0955..1a41bb9 100644
--- a/main.asm
+++ b/main.asm
@@ -32,11 +32,16 @@ macro popr x {
 ;;
 ;; This macro also defines a label LABEL_entry.
 initial_latest_entry = 0
-macro header label, name {
+macro header label, name, immediate {
   local .string_end
 
 label#_entry:
   dq initial_latest_entry
+  if immediate eq
+    db 0
+  else
+    db 1
+  end if
   db .string_end - ($ + 1)
   db name
   .string_end:
@@ -46,21 +51,19 @@ initial_latest_entry = label#_entry
 }
 
 ;; Define a Forth word that is implemented in assembly. See 'header' for details.
-macro forth_asm label, name {
-  header label, name
+macro forth_asm label, name, immediate {
+  header label, name, immediate
   dq .start
 .start:
 }
 
 ;; Define a Forth word that is implemented in Forth. (The body will be a list of
 ;; 'dq' statements.)
-macro forth label, name {
-  header label, name
-  dq docol
+macro forth label, name, immediate {
+  header label, name, immediate
+  dq DOCOL
 }
 
-
-
 segment readable executable
 
 entry main
@@ -79,13 +82,13 @@ program: dq MAIN
 ;; The codeword is the code that will be executed at the beginning of a forth
 ;; word. It needs to save the old RSI and update it to point to the next word to
 ;; execute.
-docol:
+header DOCOL, 'DOCOL'
   pushr rsi            ; Save old value of RSI on return stack; we will continue execution there after we are done executing this word
   lea rsi, [rax + 8]   ; RAX currently points to the address of the codeword, so we want to continue at RAX+8
   next                 ; Execute word pointed to by RSI
 
 ;; This word is called at the end of a Forth definition. It just needs to
-;; restore the old value of RSI (saved by 'docol') and resume execution.
+;; restore the old value of RSI (saved by 'DOCOL') and resume execution.
 forth_asm EXIT, 'EXIT'
   popr rsi
   next
@@ -119,7 +122,7 @@ forth_asm FIND, 'FIND'
 ;; entry.
 forth_asm TCFA, '>CFA'
   pop rax
-  add rax, 8                    ; [rax] = length of name
+  add rax, 8 + 1                ; [rax] = length of name
   movzx rbx, byte [rax]
   inc rax
   add rax, rbx                  ; [rax] = codeword
@@ -195,8 +198,8 @@ forth_asm READ_WORD, 'READ-WORD'
 ;; Takes a string on the stack and replaces it with the decimal number that the
 ;; string represents.
 forth_asm PARSE_NUMBER, 'PARSE-NUMBER'
-  pop [parse_number.length]     ; Length
-  pop [parse_number.buffer]     ; String pointer
+  pop rcx     ; Length
+  pop rdi     ; String pointer
 
   push rsi
   call parse_number
@@ -232,16 +235,6 @@ forth_asm TERMINATE, 'TERMINATE'
   mov rdi, 0
   syscall
 
-forth HELLO, 'HELLO'
-  dq LIT, 'H', EMIT
-  dq LIT, 'e', EMIT
-  dq LIT, 'l', EMIT
-  dq LIT, 'l', EMIT
-  dq LIT, 'o', EMIT
-  dq LIT, '!', EMIT
-  dq NEWLINE
-  dq EXIT
-
 ;; Duplicate a pair of elements.
 forth_asm PAIRDUP, '2DUP'
   pop rbx
@@ -265,8 +258,19 @@ forth_asm DROP, 'DROP'
   add rsp, 8
   next
 
+forth_asm NOT_, 'NOT'
+  pop rax
+  cmp rax, 0
+  jz .false
+.true:
+  push 0
+  next
+.false:
+  push 1
+  next
+
 ;; The INTERPRET word reads and interprets user input. It's behavior depends on
-;; the current STATE. It provides special handling for integers. (TODO)
+;; the current STATE. It provides special handling for integers.
 forth INTERPRET, 'INTERPRET'
   ;; Read word
   dq READ_WORD
@@ -274,9 +278,23 @@ forth INTERPRET, 'INTERPRET'
   ;; Stack is (word length word length).
   dq FIND                       ; Try to find word
   dq DUP_
-  dq ZBRANCH, 8 * 8             ; Check if word is found
+  dq ZBRANCH, 8 * 22            ; Check if word is found
+
+  ;; - Word is found -
+
+  dq STATE, GET, ZBRANCH, 8 * 11 ; Check whether we are in compilation or immediate mode
 
-  ;; Word is found, execute it
+  ;; (Word found, compilation mode)
+  dq DUP_, IS_IMMEDIATE, NOT_, ZBRANCH, 8 * 6 ; If the word is immediate, continue as we would in immediate mode
+
+  ;; Otherwise, we want to compile this word
+  dq TCFA
+  dq COMMA
+  dq DROP, DROP
+  dq EXIT
+
+  ;; (Word found, immediate mode)
+  ;; Execute word
   dq TCFA
   ;; Stack is (word length addr)
   dq SWAP, DROP
@@ -285,10 +303,19 @@ forth INTERPRET, 'INTERPRET'
   dq EXEC
   dq EXIT
 
-  ;; No word is found, assume it is an integer literal
+  ;; - No word is found, assume it is an integer literal -
   ;; Stack is (word length addr)
   dq DROP
   dq PARSE_NUMBER
+
+  dq STATE, GET, ZBRANCH, 8 * 5 ; Check whether we are in compilation or immediate mode
+
+  ;; (Number, compilation mode)
+  dq LIT, LIT, COMMA
+  dq COMMA
+  dq EXIT
+
+  ;; (Number, immediate mode)
   dq EXIT
 
 ;; .U prints the value on the stack as an unsigned integer in hexadecimal.
@@ -366,6 +393,18 @@ forth_asm GET, '@'
   push rax
   next
 
+forth_asm PUT_BYTE, 'C!'
+  pop rbx
+  pop rax                       ; Value
+  mov [rbx], al
+  next
+
+forth_asm GET_BYTE, 'C@'
+  pop rax
+  movzx rax, byte [rax]
+  push rax
+  next
+
 ;; Add two integers on the stack.
 forth_asm PLUS, '+'
   pop rax
@@ -383,6 +422,17 @@ forth_asm MINUS, '-'
   push rbx
   next
 
+;; Given two integers a and b on the stack, pushes the quotient and remainder of
+;; division of a by b.
+forth_asm TIMESMOD, '/MOD'
+  pop rbx                       ; b
+  pop rax                       ; a
+  mov rdx, 0
+  div rbx
+  push rax                      ; a / b
+  push rdx                      ; a % b
+  next
+
 ;; Get the location of the STATE variable. It can be set with '!' and read with
 ;; '@'.
 forth STATE, 'STATE'
@@ -408,8 +458,130 @@ forth COMMA, ','
   dq HERE, PUT                  ; Update HERE to point to the new address
   dq EXIT
 
+;; Read user input until next " character is found. Push a string containing the
+;; input on the stack as (buffer length). Note that the buffer is only valid
+;; until the next call to S" and that no more than 255 character can be read.
+forth_asm READ_STRING, 'S"'
+  push rsi
+
+  mov [.length], 0
+
+.read_char:
+  mov rax, 0
+  mov rdi, 0
+  mov rsi, .char_buffer
+  mov rdx, 1
+  syscall
+
+  mov al, [.char_buffer]
+  cmp al, '"'
+  je .done
+
+  mov rdx, .buffer
+  add rdx, [.length]
+  mov [rdx], al
+  inc [.length]
+  jmp .read_char
+
+.done:
+  pop rsi
+
+  push .buffer
+  push [.length]
+
+  next
+
+;; CREATE inserts a new header in the dictionary, and updates LATEST so that it
+;; points to the header. To compile a word, the user can then call ',' to
+;; continue to append data after the header.
+;;
+;; It takes the name of the word as a string (address length) on the stack.
+forth_asm CREATE, 'CREATE'
+  pop rcx                       ; Word string length
+  pop rdx                       ; Word string pointer
+
+  mov rdi, [here]               ; rdi = Address at which to insert this entry
+  mov rax, [latest_entry]       ; rax = Address of the previous entry
+  mov [rdi], rax                ; Insert link to previous entry
+  mov [latest_entry], rdi       ; Update LATEST to point to this word
+
+  add rdi, 8
+  mov [rdi], byte 0             ; Insert immediate flag
+
+  add rdi, 1
+  mov [rdi], byte cl            ; Insert length
+
+  ;; Insert word string
+  add rdi, 1
+
+  push rsi
+  mov rsi, rdx                  ; rsi = Word string pointer
+  rep movsb
+  pop rsi
+
+  ;; Update HERE
+  mov [here], rdi
+
+  next
+
+;; Mark the last added word as immediate.
+forth IMMEDIATE, 'IMMEDIATE', 1
+  dq LIT, 1
+  dq LATEST, GET
+  dq LIT, 8, PLUS
+  dq PUT_BYTE
+  dq EXIT
+
+;; Given the address of a word, return 0 if the given word is not immediate.
+forth IS_IMMEDIATE, 'IMMEDIATE?'
+  dq LIT, 8, PLUS
+  dq GET_BYTE
+  dq EXIT
+
+;; Enter immediate mode, immediately
+forth INTO_IMMEDIATE, '[', 1
+  dq LIT, 0, STATE, PUT_BYTE
+  dq EXIT
+
+;; Enter compilation mode
+forth OUTOF_IMMEDIATE, ']'
+  dq LIT, 1, STATE, PUT_BYTE
+  dq EXIT
+
+forth_asm TICK, "'"
+  lodsq
+  push rax
+  next
+
+forth_asm ROT, 'ROT'
+  pop rax
+  pop rbx
+  pop rdx
+  push rax
+  push rdx
+  push rbx
+  next
+
+forth_asm PICK, 'PICK'
+  pop rax
+  lea rax, [rsp + 8 * rax]
+  mov rax, [rax]
+  push rax
+  next
+
+forth_asm EQL, '='
+  pop rax
+  pop rbx
+  cmp rax, rbx
+  je .eq
+.noteq:
+  push 0
+  next
+.eq:
+  push 1
+  next
+
 forth MAIN, 'MAIN'
-  dq HELLO
   dq INTERPRET
   dq BRANCH, -8 * 2
   dq TERMINATE
@@ -430,6 +602,10 @@ FIND.rsi dq ?
 READ_WORD.rsi dq ?
 READ_WORD.rbp dq ?
 
+READ_STRING.char_buffer db ?
+READ_STRING.buffer rb $FF
+READ_STRING.length dq ?
+
 DOTU.chars db '0123456789ABCDEF'
 DOTU.buffer rq 16               ; 64-bit number has no more than 16 digits in hex
 DOTU.rbuffer rq 16
@@ -438,7 +614,7 @@ DOTU.printed_length dq ?
 
 ;; Reserve space for compiled words, accessed through HERE.
 here dq here_top
-here_top rq $2000
+here_top rq $4000
 
 ;; Return stack
 rq $2000