; This is a forth interpreter for x86_64 (elf64)
	format elf64 executable
	entry main

include 'machine.asm'

;;; ============================================================

	segment readable writable executable

	WORD return_stack,'RS',dovariable
	;; The return stack
	rb 1048576		; 1 Mb return stack
RS_TOP:				; The initial rbp
	
	WORD data_stack,'DS',dovariable
	;; The data stack
	rb 1048576		; 1 Mb data stack
DS_TOP:				; The initial rsp

	WORD inline_code,'[ASM]',fasm
	;; ( -- )
	;; This transitions execution into inline assembler in the
	;; calling word defintion. Note that it stops advancing rsi;
	;; code should use FORTH macro to reenter forth execution, or
	;; exit to the calling definition via "jmp exit".
	jmp qword rsi

	WORD p_exit, 'EXIT',fasm
	;; ( -- ) ( R: addr -- )
	;; Returns execution to the calling definition as per the
	;; return stack.
exit:
	popr rsi
	next

;;; Execution semantics for FORTH defition word
;;; At entry, rsi points into the calling definition, at the cell
;;; following the cell indicating this word, rax points to the CFA of
;;; this word.
doforth:
	pushr rsi
	lea rsi, [rax+8] 	; rsi = the DFA of the rax word
	next

;;; Execution semantics for DOES>
;;; The cell at [cfa-8] holds an adjustment offset.
dodoes:
	pushr rsi
	lea rsi, [rax+8] 	; rsi = the DFA of the rax word
	add rsi,[rax-8]		; adjust rsi to the DOES> part
	next

	;; Execution semantics for a variable ( -- addr )
	;; rax points to CFA field
dovariable:
	add rax,8
	push rax
	next

	;; Execution semantics for a constant ( -- v )
	;; rax points to CFA field
dovalue:
	push qword [rax+8]
	next

	;; Execution semantics for a string constant ( -- addr n )
	;; rax points to CFA field
dostring:
	add rax,8
	xor rbx,rbx
	mov bl,[rax]
	inc rax
	push rax
	push rbx
	next

include 'wordlists.asm'
include 'syscalls.asm'
include 'memory.asm'
include 'stack.asm'
include 'math.asm'
include 'stdio.asm'

	WORD p_program_version,'PROGRAM_VERSION',dostring
	STRING 'RRQ Forth version 0.1 - 2021-05-13',10

	WORD p_stdin,'STDIN',dovalue
	;; Initialised to hold a STREAM for fd 0
	dq 0
	
	WORD p_quit,'QUIT',fasm
	;; QUIT is the program entry point ********************
main:
	mov rsp,DS_TOP
	mov rbp,RS_TOP
	;; Initialize STREAM STDIN
	push 0
	push 10000
	DOFORTH p_stream
	pop qword [p_stdin_DFA]

	;; read a word
	push qword 1		; ( fd ) =stdout
	push qword [p_stdin_DFA]
	FORTH
	dq p_read_word		; ( fd s n )
	dq sys_write
	ENDFORTH

	push qword 1			; stdout
	DOFORTH p_program_version	; version string => ( s n )
	DOFORTH sys_write		; printout
	pop rax				; ignore errors
	
	push 0
	DOFORTH sys_exit

	;; TERMINATE0 terminates the program with code 0
	;; ( v -- )
	WORD terminate, 'TERMINATE',fasm
	pop rdx
terminate_special:
	mov eax,60
	syscall

last_word:
	;; FORTH is the last word of VOCABULARY FORTH
	WORD forth,'FORTH',dovalue
	dq forth_TFA
	dq 0

	
heap_start: