;; This code is intended for an embedded binary with an "archive" of
;; files appended to it. The appended archive is marked by a array of
;; 40 "x", and consists by archive elements the format of
;; "pathname\nsize\nbytes[size]".
;;
;; When there is an in-core archive, then the first member will be
;; invoked as "main script".
;;
;; archives:archives is a hashmap for loadable files
;; core:core is the running binary file
;;
;; The "archive" context holds utility code.
;; archive:main is the name of the first in-core member.
;; archive:incore is the byte position into core for the archive.
;;
;; Use (archives member pathname) to register that the file "member"
;; should be looked up in the ar style archive of the given pathname.
;;
;; Use (archive pathname) to register all members of the nominated ar
;; style archive.

;; This is a hashmap of loaded files
(new Tree 'archives)

;; A copy of the executable
(define core:core (read-file "/proc/self/exe"))

(context 'archive)

(setf main nil)

(constant 'AR "/usr/bin/ar" 'TAR "/bin/tar" 'FILE "/usr/bin/file")

(define (tar-able PATH)
  (when (file? FILE)
    (if (exec (format "%s -Z %s" FILE PATH))
        (find " tar archive" ($it 0)))))

;; Install indexes for all members of the given archive file
(define (archive:archive PATH)
  ;;(write-line 2 (string (list 'archive PATH)))
  (map (fn (F) (archives F PATH) F)
       (if (directory? PATH) (directory PATH "^[^.]")
         (ends-with PATH ".a") (exec (format "%s t %s" AR PATH))
         (tar-able PATH) (exec (format "%s tf %s" TAR PATH))
         '()
         )))

;; Read a member of an external archive
(define (get-stdout CMD)
  (let ((I (pipe)) (O (pipe)) (DATA "") (ALL "")
        (SUB (fn (I O)
               (map close (list (I 1) (O 0) 0))
               (process CMD (I 0) (O 1)))))
    (fork (SUB I O))
    (close (O 1)) (close (I 0)) (close (I 1))
    (while (> (or (read (O 0) DATA 1000000) 0)) (extend ALL DATA))
    (close (I 0))
    ALL))

;; Read an archive member. The given PATH is either a string path for
;; an external archive file or the (position length) list for an
;; incore packaged member.
(define (get PATH MEMBER)
  (if (list? PATH) ((PATH 0) (PATH 1) core)
    (directory? PATH) (read-file (format "%s/%s" PATH MEMBER))
    (ends-with PATH ".a") (get-stdout (format "%s p %s %s" AR PATH MEMBER))
    (tar-able PATH) (get-stdout (format "%s xOf %s %s" TAR PATH MEMBER))
    ))

;; Discover and load an in-core archive by means of a marker row of 40
;; "x", and then a series of pathname\nsize\nbytes[size] members.
(if (find (dup "x" 40) core nil 300000)
    (let ((P (+ $it 41))) ; skip marker and newline
      (constant 'incore P)
      (while (regex "([^\n]+)\n([^\n]+)\n" core 0 P)
        (let ((N $1) (S (int $2)) (L (length $0)))
          (inc P L)
          (unless main (setf main N))
          (archives N (list P S))
          (inc P S))))
  (write-line 2 (string "not packed")))

(context MAIN)

(constant
   'load
   (letex ((LOAD load) (CTX '(if (1 (args)) (args 1) MAIN)))
     (fn () (if (archives (args 0))
                (eval-string (archive:get $it (args 0)) CTX)
              (LOAD (args 0) (eval CTX)))))
   'read-file
   (letex ((READ-FILE read-file) (CTX '(if (1 (args)) (args 1) MAIN)))
     (fn ()
       (if (archives (args 0)) (archive:get $it (args 0) CTX)
         (READ-FILE (args 0)))))
   'file?
   (letex ((FILE? file?))
     (fn () (if (archives (args 0)) true (FILE? (args 0)))))
   )

(when archive:main (load archive:main) (exit 0))