slirc.pl

   1 #!/usr/bin/perl -w
   2 # slirc.pl: local Slack IRC gateway
   3 # Copyright (C) 2017-2019 Daniel Beer <dlbeer@gmail.com>
   4 #
   5 # Permission to use, copy, modify, and/or distribute this software for any
   6 # purpose with or without fee is hereby granted, provided that the above
   7 # copyright notice and this permission notice appear in all copies.
   8 #
   9 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  10 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  11 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  12 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  13 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  14 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  15 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  16 #
  17 # To run, create a configuration file with the following content:
  18 #
  19 #     slack_token=<legacy API token>
  20 #     password=<password of your choice>
  21 #     port=<port>
  22 #
  23 # Then run ./slirc.pl <config-file>. Connect to the chosen port on
  24 # 127.0.0.1 with your chosen password.
  25 #
  26 # Updated 2018-05-15 to add support for listening on Unix domain sockets
  27 # by Colin Watson <cjwatson@chiark.greenend.org.uk>. To use this feature
  28 # with an IRC client supporting Unix domain connections, add the line
  29 # "unix_socket=<path>" to the config file.
  30 #
  31 # Updated 2019-02-18:
  32 # - HTML entities are now escaped/unescaped properly
  33 # - Channel IDs are translated with the correct sigil
  34 # - You can now close accumulated group chats. This is mapped to
  35 #   JOIN/PART (the behaviour of JOIN/PART for public channels is
  36 #   unaffected)
  37 # - IRC-side PING checks are now more lenient, to work around bugs in
  38 #   some IRC clients
  39 # - Added X commands for debug dumps and dynamically switching protocol
  40 #   debug on/off
  41 #
  42 # Updated 2019-05-08 based on changes from Neia Finch to improve
  43 # support for bots.
  44
  45 use strict;
  46 use warnings;
  47 use utf8;
  48
  49 use AnyEvent;
  50 use AnyEvent::HTTP;
  51 use AnyEvent::Socket;
  52 use AnyEvent::WebSocket::Client;
  53 use URI::Encode qw(uri_encode);
  54 use Data::Dumper;
  55 use Time::localtime;
  56 use Digest::SHA qw(sha256);
  57 use JSON;
  58
  59 my $VERSION = "20190225";
  60 my $start_time = time();
  61 my %config;
  62
  63 $| = 1;
  64
  65 ########################################################################
  66 # Global chat state
  67 ########################################################################
  68
  69 my $connected;                  # Is the RTM connection ready?
  70 my $self_id;                    # Slack ID of our own user, or undef
  71
  72 my %channels;                   # Slack ID -> channel hash ref
  73 my %channels_by_name;           # irc_lcase -> channel hash ref
  74 # Properties:
  75 # - Id: Slack ID
  76 # - Members: Slack ID set
  77 # - Name: text (IRC name)
  78 # - Topic: text
  79
  80 my %users;                      # Slack ID -> user hash ref
  81 my %users_by_name;              # irc_lcase -> user hash ref
  82 my %users_by_dmid;              # Slack DMID -> user hash ref
  83 # Properties:
  84 # - Id: Slack ID
  85 # - Name: text (IRC name)
  86 # - Channels: Slack ID set
  87 # - Realname: text
  88 # - DMId: DM session ID (may be undefined, or blank if open in progress)
  89 # - TxQueue: messages awaiting transmission if no DM open
  90
  91 ########################################################################
  92 # IRC names
  93 ########################################################################
  94
  95 # Canonicalize an IRC name
  96 sub irc_lcase {
  97     my $name = lc(shift);
  98
  99     $name =~ s/\[/{/g;
 100     $name =~ s/]/}/g;
 101     $name =~ s/\|/\\/g;
 102     $name =~ s/\^/~/g;
 103
 104     return $name;
 105 }
 106
 107 # Compare two names
 108 sub irc_eq {
 109     my ($a, $b) = @_;
 110
 111     return irc_lcase($a) eq irc_lcase($b);
 112 }
 113
 114 # Choose an unused valid name with reference to the hash
 115 sub irc_pick_name {
 116     my ($name, $hash) = @_;
 117
 118     $name =~ s/[#,<>!\0\r\n: ]/_/g;
 119
 120     return $name if length($name) && irc_lcase($name) ne "x" &&
 121         !defined($hash->{irc_lcase($name)});
 122
 123     my $i = 1;
 124
 125     for (;;) {
 126         my $prop = "$name$i";
 127
 128         return $prop unless defined($hash->{irc_lcase($prop)});
 129         $i++;
 130     }
 131 }
 132
 133 ########################################################################
 134 # IRC server
 135 ########################################################################
 136
 137 # Forward decls to RTM subsystem
 138 sub rtm_send;
 139 sub rtm_send_to_user;
 140 sub rtm_apicall;
 141 sub rtm_download;
 142 sub rtm_destroy;
 143 sub rtm_update_join;
 144 sub rtm_update_part;
 145
 146 my %irc_clients;
 147
 148 sub irc_send_args {
 149     my ($c, $source, $short, $long) = @_;
 150
 151     $source =~ s/[\t\r\n\0 ]//g;
 152     $source =~ s/^://g;
 153     my @arg = (":$source");
 154
 155     for my $a (@$short) {
 156         $a =~ s/[\t\r\n\0 ]//g;
 157         $a =~ s/^://g;
 158         utf8::encode($a);
 159         $a = "*" unless length($a);
 160         push @arg, $a;
 161     }
 162
 163     if (defined($long)) {
 164         $long =~ s/[\r\n\0]/ /g;
 165         utf8::encode($long);
 166         push @arg, ":$long";
 167     }
 168
 169     my $line = join(' ', @arg);
 170     print "IRC $c->{Handle} SEND: $line\n" if $config{debug_dump};
 171     $c->{Handle}->push_write("$line\r\n");
 172 }
 173
 174 sub irc_send_num {
 175     my ($c, $num, $short, $long) = @_;
 176     my $dst = $c->{Nick};
 177
 178     $dst = "*" unless defined($c->{Nick});
 179     irc_send_args $c, "localhost",
 180         [sprintf("%03d", $num), $dst, @$short], $long;
 181 }
 182
 183 sub irc_send_from {
 184     my ($c, $uid, $short, $long) = @_;
 185     my $user = $users{$uid};
 186     my $nick = $uid eq $self_id ? $c->{Nick} : $user->{Name};
 187
 188     irc_send_args $c, "$nick!$user->{Id}\@localhost", $short, $long;
 189 }
 190
 191 sub irc_disconnect {
 192     my ($c, $msg) = @_;
 193
 194     print "IRC $c->{Handle} DISCONNECT: $msg\n";
 195     delete $irc_clients{$c->{Handle}};
 196     $c->{Handle}->destroy;
 197 }
 198
 199 sub irc_disconnect_all {
 200     print "IRC: disconnect all\n";
 201     foreach my $k (keys %irc_clients) {
 202         $irc_clients{$k}->{Handle}->destroy;
 203     }
 204     %irc_clients = ();
 205 }
 206
 207 sub irc_send_names {
 208     my ($c, $chan) = @_;
 209     my $i = 0;
 210     my @ulist = keys %{$chan->{Members}};
 211
 212     while ($i < @ulist) {
 213         my $n = @ulist - $i;
 214         $n = 8 if $n > 8;
 215         my $chunk = join(' ', map {
 216             $_ eq $self_id ? $c->{Nick} : $users{$_}->{Name}
 217         } @ulist[$i .. ($i + $n - 1)]);
 218         irc_send_num $c, 353, ['@', "#$chan->{Name}"], $chunk;
 219         $i += $n;
 220     }
 221
 222     irc_send_num $c, 366, ["#$chan->{Name}"], "End of /NAMES list";
 223 }
 224
 225 sub irc_server_notice {
 226     my ($c, $msg) = @_;
 227     my $nick = $c->{Nick};
 228
 229     $nick = "*" unless defined($nick);
 230     irc_send_args $c, "localhost", ["NOTICE", $nick], $msg;
 231 }
 232
 233 sub irc_gateway_notice {
 234     my ($c, $msg) = @_;
 235     my $nick = $c->{Nick};
 236
 237     $nick = "*" unless defined($nick);
 238     irc_send_args $c, "X!X\@localhost", ["NOTICE", $nick], $msg;
 239 }
 240
 241 sub irc_notify_away {
 242     my $c = shift;
 243     my $user = $users{$self_id};
 244     my ($num, $msg);
 245
 246     if ($user->{Presence} eq 'away') {
 247         $num = 306;
 248         $msg = "You have been marked as being away";
 249     } else {
 250         $num = 305;
 251         $msg = "You are no longer marked as being away";
 252     }
 253
 254     irc_send_num $c, $num, [], $msg if $c->{Ready};
 255 }
 256
 257 sub irc_broadcast_away {
 258     for my $k (keys %irc_clients) {
 259         my $c = $irc_clients{$k};
 260         irc_notify_away $c if $c->{Ready};
 261     }
 262 }
 263
 264 sub irc_send_motd {
 265     my $c = shift;
 266     my @banner =
 267       (
 268        '     _ _                  _',
 269        ' ___| (_)_ __ ___   _ __ | |',
 270        '/ __| | | \'__/ __| | \'_ \| |',
 271        '\__ \ | | | | (__ _| |_) | |',
 272        '|___/_|_|_|  \___(_) .__/|_|',
 273        '                   |_|',
 274        'slirc.pl, Copyright (C) 2017-2019 Daniel Beer <dlbeer@gmail.com>'
 275       );
 276
 277     for my $x (@banner) {
 278         irc_send_num $c, 372, [], $x;
 279     }
 280     irc_send_num $c, 376, [], "End of /MOTD command";
 281 }
 282
 283 sub irc_check_welcome {
 284     my $c = shift;
 285
 286     if (defined $c->{Nick} && defined $c->{User} &&
 287         (!$config{password} || defined $c->{Password}) &&
 288         !$c->{Authed}) {
 289         if (!$config{password} ||
 290             sha256($c->{Password}) eq sha256($config{password})) {
 291             $c->{Authed} = 1;
 292         } else {
 293             irc_server_notice $c, "Incorrect password";
 294             irc_disconnect $c, "Incorrect password";
 295             return;
 296         }
 297     }
 298
 299     return unless $c->{Authed} && !$c->{Ready} && $connected;
 300
 301     my $u = $users_by_name{irc_lcase($c->{Nick})};
 302     if (defined($u) && ($u->{Id} ne $self_id)) {
 303         irc_server_notice $c, "Nick already in use";
 304         irc_disconnect $c, "Nick already in use";
 305         return;
 306     }
 307
 308     my $lt = localtime($start_time);
 309
 310     irc_send_num $c, 001, [], "slirc.pl IRC-to-Slack gateway";
 311     irc_send_num $c, 002, [], "This is slirc.pl version $VERSION";
 312     irc_send_num $c, 003, [], "Server started " . ctime($start_time);
 313     irc_send_motd $c;
 314     $c->{Ready} = 1;
 315
 316     my $user = $users{$self_id};
 317
 318     for my $k (keys %{$user->{Channels}}) {
 319         my $chan = $channels{$k};
 320         irc_send_from $c, $self_id, ["JOIN", "#$chan->{Name}"];
 321         irc_send_num $c, 332, ["#$chan->{Name}"], $chan->{"Topic"};
 322         irc_send_names $c, $chan;
 323     }
 324
 325     irc_notify_away $c;
 326 }
 327
 328 sub irc_check_welcome_all {
 329     foreach my $k (keys %irc_clients) {
 330         irc_check_welcome $irc_clients{$k};
 331     }
 332 }
 333
 334 sub irc_broadcast_nick {
 335     my ($id, $newname) = @_;
 336     return if $id eq $self_id;
 337
 338     for my $k (keys %irc_clients) {
 339         my $c = $irc_clients{$k};
 340         irc_send_from $c, $id, ["NICK", $newname] if $c->{Ready};
 341     }
 342 }
 343
 344 sub irc_broadcast_join {
 345     my ($uid, $chid) = @_;
 346     my $chan = $channels{$chid};
 347
 348     for my $k (keys %irc_clients) {
 349         my $c = $irc_clients{$k};
 350         next unless $c->{Ready};
 351
 352         if ($uid eq $self_id) {
 353             irc_send_from $c, $self_id, ["JOIN", "#$chan->{Name}"];
 354             irc_send_num $c, 332, ["#$chan->{Name}"], $chan->{Topic};
 355             irc_send_names $c, $chan;
 356         } else {
 357             irc_send_from $c, $uid, ["JOIN", "#$chan->{Name}"];
 358         }
 359     }
 360 }
 361
 362 sub irc_broadcast_part {
 363     my ($uid, $chid) = @_;
 364     my $chan = $channels{$chid};
 365
 366     for my $k (keys %irc_clients) {
 367         my $c = $irc_clients{$k};
 368         next unless $c->{Ready};
 369         irc_send_from $c, $uid, ["PART", "#$chan->{Name}"];
 370     }
 371 }
 372
 373 sub irc_send_who {
 374     my ($c, $chname, $u) = @_;
 375
 376     my $user = $users{$u};
 377     my $nick = $u eq $self_id ? $c->{Nick} : $user->{Name};
 378     my $here = $user->{Presence} eq 'away' ? 'G' : 'H';
 379
 380     irc_send_num $c, 352, [$chname, $user->{Id}, "localhost", "localhost",
 381                            $nick, $here], "0 $user->{Realname}";
 382 }
 383
 384 sub irc_send_whois {
 385     my ($c, $uid) = @_;
 386     my $u = $users{$uid};
 387     my $nick = $uid eq $self_id ? $c->{Nick} : $u->{Name};
 388
 389     irc_send_num $c, 311,
 390         [$nick, $u->{Id}, "localhost", "*"], $u->{Realname};
 391     irc_send_num $c, 312, [$nick, "localhost"], "slirc.pl";
 392     my $clist = join(' ', map { "#" . $channels{$_}->{Name} }
 393                           keys %{$u->{Channels}});
 394     irc_send_num $c, 319, [$nick], $clist;
 395     irc_send_num $c, 301, [$nick], "away" if $u->{Presence} eq 'away';
 396 }
 397
 398 sub irc_invite_or_kick {
 399     my ($c, $action, $name, $chname) = @_;
 400
 401     $chname =~ s/^#//;
 402     my $chan = $channels_by_name{irc_lcase($chname)};
 403
 404     unless (defined $chan) {
 405         irc_send_num $c, 401, ["#$chname"], "No such nick/channel";
 406         return;
 407     }
 408
 409     my $what = $chan->{Type} eq "C" ? "channels" : "groups";
 410
 411     foreach (split(/,/, $name)) {
 412         my $user = $users_by_name{irc_lcase($_)};
 413
 414         if (defined $user) {
 415             rtm_apicall "$what.$action", { user => $user->{Id},
 416                                            channel => $chan->{Id} };
 417         } else {
 418             irc_send_num $c, 401, [$user], "No such nick/channel";
 419         }
 420     }
 421 }
 422
 423 my %gateway_command = (
 424     "debug_dump_state" => sub {
 425         my $c = shift;
 426         irc_gateway_notice $c, "Dumping debug state on stdout";
 427         print Dumper({ "connected" => $connected,
 428                        "self_id", => $self_id,
 429                        "%channels" => \%channels,
 430                        "%channels_by_name" => \%channels_by_name,
 431                        "users" => \%users,
 432                        "users_by_name" => \%users_by_name,
 433                        "users_by_dmid" => \%users_by_dmid
 434                      });
 435     },
 436     "debug_dump" => sub {
 437         my ($c, $arg) = @_;
 438         $config{debug_dump} = $arg ? 1 : 0 if defined $arg;
 439         irc_gateway_notice $c, "Protocol debug is " .
 440           ($config{debug_dump} ? "on" : "off");
 441     },
 442     "newgroup" => sub {
 443         my ($c, $name) = @_;
 444         unless (defined($name)) {
 445             irc_gateway_notice $c, "Syntax: newgroup <name>";
 446             return;
 447         }
 448         $name =~ s/^#//;
 449         irc_gateway_notice $c, "Creating group $name";
 450         rtm_apicall "groups.create", { name => $name };
 451     },
 452     "newchan" => sub {
 453         my ($c, $name) = @_;
 454         unless (defined($name)) {
 455             irc_gateway_notice $c, "Syntax: newchan <name>";
 456             return;
 457         }
 458         $name =~ s/^#//;
 459         irc_gateway_notice $c, "Creating channel $name";
 460         rtm_apicall "channels.create", { name => $name };
 461     },
 462     "archive" => sub{
 463         my ($c, $name) = @_;
 464         unless (defined($name)) {
 465             irc_gateway_notice $c, "Syntax: archive <name>";
 466             return;
 467         }
 468         $name =~ s/^#//;
 469         my $g = $channels_by_name{irc_lcase($name)};
 470         my $what = $g->{Type} eq "C" ? "channels" : "groups";
 471         if (defined $g) {
 472             irc_gateway_notice $c, "Archiving $name";
 473             rtm_apicall "$what.archive", { channel => $g->{Id} };
 474         } else {
 475             irc_gateway_notice $c, "No such channel: $name";
 476         }
 477     },
 478     "close" => sub{
 479         my ($c, $name) = @_;
 480         unless (defined($name)) {
 481             irc_gateway_notice $c, "Syntax: close <name>";
 482             return;
 483         }
 484
 485         $name =~ s/^#//;
 486         my $g = $channels_by_name{irc_lcase($name)};
 487         my $what = $g->{Type} eq "C" ? "channels" : "groups";
 488         if (defined $g) {
 489             irc_gateway_notice $c, "Closing $name";
 490             rtm_apicall "$what.close", { channel => $g->{Id} };
 491         } else {
 492             irc_gateway_notice $c, "No such channel: $name";
 493         }
 494     },
 495     "cat" => sub {
 496         my ($c, $fileid) = @_;
 497         unless (defined($fileid)) {
 498             irc_gateway_notice $c, "Syntax: cat <fileid> <filename>";
 499             return;
 500         }
 501
 502         rtm_apicall "files.info", { file => $fileid }, sub {
 503             my $data = shift;
 504             return unless defined $data;
 505
 506             my $body = $data->{content};
 507
 508             if (length($body) > 65536) {
 509                 irc_gateway_notice $c, "File too big";
 510             } else {
 511                 irc_gateway_notice $c, "---- BEGIN $fileid ----";
 512                 foreach (split(/\n/, $body)) {
 513                     irc_gateway_notice $c, "$_";
 514                 }
 515                 irc_gateway_notice $c, "---- END $fileid ----";
 516             }
 517         };
 518     },
 519     "disconnect" => sub {
 520         my ($c) = @_;
 521         irc_gateway_notice $c, "Disconnecting";
 522         rtm_destroy "User disconnection request";
 523     },
 524     "delim" => sub {
 525         my ($c, $nick) = @_;
 526         unless (defined($nick)) {
 527             irc_gateway_notice $c, "Syntax: delim <name>";
 528             return;
 529         }
 530         my $user;
 531
 532         if ($nick eq $c->{Nick}) {
 533             $user = $users{$self_id};
 534         } else {
 535             $user = $users_by_name{irc_lcase($nick)};
 536             $user = undef if $user->{Id} eq $self_id;
 537         }
 538
 539         unless (defined($user)) {
 540             irc_gateway_notice $c, "No such nick: $nick";
 541             return;
 542         }
 543
 544         unless (defined $user->{DMId}) {
 545             irc_gateway_notice $c, "DM already closed for $nick";
 546             return;
 547         }
 548
 549         irc_gateway_notice $c, "Closing DM for $nick";
 550         rtm_apicall "im.close", { channel => $user->{DMId} };
 551     },
 552 );
 553
 554 my %irc_command = (
 555     "NICK" => sub {
 556         my ($c, $newnick) = @_;
 557         return unless defined($newnick);
 558
 559         if (defined $c->{Nick}) {
 560             my $u = $users_by_name{irc_lcase($newnick)};
 561             if (defined($u) && ($u->{Id} ne $self_id)) {
 562                 irc_send_num $c, 433, [$newnick], "Nickname is already in use";
 563             } else {
 564                 irc_send_from $c, $self_id, ["NICK"], $newnick;
 565                 $c->{Nick} = $newnick;
 566             }
 567         } else {
 568             $c->{Nick} = $newnick;
 569             irc_check_welcome $c;
 570         }
 571     },
 572     "PASS" => sub {
 573         my ($c, $pass) = @_;
 574
 575         $c->{Password} = $pass;
 576         irc_check_welcome $c;
 577     },
 578     "USER" => sub {
 579         my ($c, @arg) = @_;
 580         return unless scalar(@arg) >= 4;
 581
 582         $c->{User} = $arg[0];
 583         $c->{Realname} = $arg[3];
 584         irc_check_welcome $c;
 585     },
 586     "AWAY" => sub {
 587         my ($c, $msg) = @_;
 588         return unless $c->{Ready};
 589         my $presence = defined $msg ? "away" : "auto";
 590         rtm_apicall "users.setPresence", { presence => $presence };
 591     },
 592     "PING" => sub {
 593         my ($c, $reply) = @_;
 594         $reply = "" unless defined($reply);
 595         irc_send_args $c, "localhost", ["PONG"], $reply;
 596     },
 597     "INVITE" => sub {
 598         my ($c, $name, $chname) = @_;
 599         return unless $c->{Ready};
 600         irc_invite_or_kick $c, "invite", $name, $chname;
 601     },
 602     "KICK" => sub {
 603         my ($c, $name, $chname) = @_;
 604         return unless $c->{Ready};
 605         irc_invite_or_kick $c, "kick", $name, $chname;
 606     },
 607     "JOIN" => sub {
 608         my ($c, $name) = @_;
 609         return unless $c->{Ready};
 610         return unless defined($name);
 611
 612         foreach my $n (split(/,/, $name)) {
 613             $n =~ s/^#//;
 614             my $chan = $channels_by_name{irc_lcase($n)};
 615             if (not defined $chan) {
 616                 irc_send_num $c, 401, ["#$n"], "No such nick/channel";
 617             } elsif ($chan->{Members}->{$self_id}) {
 618                 # Already joined
 619             } elsif ($chan->{Type} eq "G") {
 620                 rtm_apicall "groups.open", { channel => $chan->{Id} };
 621                 irc_broadcast_join $self_id, $chan->{Id}
 622                   if rtm_update_join $self_id, $chan->{Id};
 623             } else {
 624                 #rtm_apicall "channels.join", { channel => $chan->{Id} };
 625                 rtm_apicall "conversations.join", { channel => $chan->{Id} };
 626             }
 627         }
 628     },
 629     "MODE" => sub {
 630         my ($c, $arg, $what) = @_;
 631         return unless $c->{Ready};
 632         return unless defined($arg);
 633
 634         $what = $what || "";
 635
 636         if ($arg eq $c->{Nick}) {
 637             irc_send_num $c, 221, [], "+i";
 638         } elsif ($arg =~ /^#(.*)$/) {
 639             my $chan = $channels_by_name{$1};
 640
 641             if (defined $chan) {
 642                 if ($what eq "b") {
 643                     irc_send_num $c, 368, ["#$chan->{Name}"],
 644                         "End of channel ban list";
 645                 } else {
 646                     irc_send_num $c, 324,
 647                         ["#$chan->{Name}",
 648                          ($chan->{Type} eq "G" ? "+ip" : "+p")];
 649                     irc_send_num $c, 329,
 650                         ["#$chan->{Name}", $start_time];
 651                 }
 652             } else {
 653                 irc_send_num $c, 403, [$arg], "No such channel";
 654             }
 655         } else {
 656             irc_send_num $c, 403, [$arg], "No such channel";
 657         }
 658     },
 659     "TOPIC" => sub {
 660         my ($c, $name, $topic) = @_;
 661         return unless defined($name) && defined($topic);
 662         return unless $c->{Ready};
 663
 664         $name =~ s/^#//;
 665         my $chan = $channels_by_name{irc_lcase($name)};
 666         unless (defined($chan)) {
 667             irc_send_num $c, 401, ["#$name"], "No such nick/channel";
 668             return;
 669         }
 670
 671         my $what = $chan->{Type} eq "C" ? "channels" : "groups";
 672
 673         rtm_apicall "$what.setTopic", { channel => $chan->{Id},
 674                                         topic => $topic };
 675     },
 676     "PART" => sub {
 677         my ($c, $name) = @_;
 678         return unless $c->{Ready};
 679         return unless defined($name);
 680
 681         foreach my $n (split(/,/, $name)) {
 682             $n =~ s/^#//;
 683             my $chan = $channels_by_name{irc_lcase($n)};
 684             if (not defined($chan)) {
 685                 irc_send_num $c, 401, ["#$n"], "No such nick/channel";
 686             } elsif ($chan->{Members}->{$self_id}) {
 687                 if ($chan->{Type} eq "G") {
 688                     rtm_apicall "groups.close", { channel => $chan->{Id} };
 689                     irc_broadcast_part $self_id, $chan->{Id}
 690                       if rtm_update_part $self_id, $chan->{Id};
 691                 } else {
 692                     rtm_apicall "channels.leave", { channel => $chan->{Id} };
 693                 }
 694             }
 695         }
 696     },
 697     "LIST" => sub {
 698         my ($c, @arg) = @_;
 699         return unless $c->{Ready};
 700
 701         irc_send_num $c, 321, ["Channel"], "Users Name";
 702         foreach my $chid (keys %channels) {
 703             my $chan = $channels{$chid};
 704             my $n = keys %{$chan->{Members}};
 705
 706             irc_send_num $c, 322, ["#$chan->{Name}", $n], $chan->{Topic};
 707         }
 708         irc_send_num $c, 323, [], "End of /LIST";
 709     },
 710     "WHOIS" => sub {
 711         my ($c, $nicklist) = @_;
 712         return unless $c->{Ready};
 713         return unless defined($nicklist);
 714         my $some = 0;
 715
 716         for my $nick (split(/,/, $nicklist)) {
 717             if (irc_eq($nick, "x")) {
 718                 irc_send_num $c, 311,
 719                     ["X", "X", "localhost", "*"], "Gateway service";
 720                 irc_send_num $c, 312, ["X", "localhost"], "slirc.pl";
 721             } elsif (irc_eq($nick, $c->{Nick})) {
 722                 irc_send_whois $c, $self_id;
 723             } else {
 724                 my $user;
 725
 726                 if ($nick =~ /^.*!([^@]*)/) {
 727                     $user = $users{$1};
 728                 } else {
 729                     $user = $users_by_name{irc_lcase($nick)};
 730                     $user = undef if defined($user) && $user->{Id} eq $self_id;
 731                 }
 732
 733                 if (defined($user)) {
 734                     irc_send_whois $c, $user->{Id};
 735                 } else {
 736                     irc_send_num $c, 401, [$nick], "No such nick/channel";
 737                 }
 738             }
 739         }
 740
 741         irc_send_num $c, 318, [$nicklist], "End of /WHOIS list";
 742     },
 743     "NAMES" => sub {
 744         my ($c, $name) = @_;
 745         return unless $c->{Ready};
 746         return unless defined($name);
 747
 748         my $n = $name;
 749         $n =~ s/^#//;
 750         my $chan = $channels_by_name{irc_lcase($n)};
 751         unless (defined($chan)) {
 752             irc_send_num $c, 401, [$name], "No such nick/channel";
 753             return;
 754         }
 755
 756         irc_send_names $c, $chan;
 757     },
 758     "WHO" => sub {
 759         my ($c, $name) = @_;
 760         return unless $c->{Ready};
 761
 762         if (!defined($name)) {
 763             foreach my $u (keys %users) {
 764                 irc_send_who $c, "*", $u;
 765             }
 766             irc_send_num $c, 352, ["*", "X", "localhost", "localhost",
 767                                    "X", "H"], "0 Gateway service";
 768         } elsif (irc_eq($name, "X")) {
 769             irc_send_num $c, 352, ["*", "X", "localhost", "localhost",
 770                                    "X", "H"], "0 Gateway service";
 771         } elsif ($name =~ /^.*!([^@]*)/) {
 772             unless (exists $users{$1}) {
 773                 irc_send_num $c, 401, [$name], "No such nick/channel";
 774                 return;
 775             }
 776
 777             irc_send_who $c, $name, $1;
 778         } elsif ($name =~ /^#(.*)$/) {
 779             my $chan = $channels_by_name{irc_lcase($1)};
 780
 781             unless (defined($chan)) {
 782                 irc_send_num $c, 401, [$name], "No such nick/channel";
 783                 return;
 784             }
 785
 786             foreach my $u (keys %{$chan->{Members}}) {
 787                 irc_send_who $c, "#$chan->{Name}", $u;
 788             }
 789         } else {
 790             my $user = $users_by_name{irc_lcase($name)};
 791
 792             unless (defined($user)) {
 793                 irc_send_num $c, 401, [$name], "No such nick/channel";
 794                 return;
 795             }
 796
 797             irc_send_who $c, $name, $self_id;
 798         }
 799
 800         $name = "*" unless defined($name);
 801         irc_send_num $c, 315, [$name], "End of /WHO list";
 802     },
 803     "MOTD" => sub {
 804         my $c = shift;
 805         irc_send_motd $c;
 806     },
 807     "PRIVMSG" => sub {
 808         my ($c, $namelist, $msg) = @_;
 809         return unless $c->{Ready};
 810         return unless defined($namelist) && defined($msg);
 811
 812         $msg =~ s/&/&amp;/g;
 813         $msg =~ s/</&lt;/g;
 814         $msg =~ s/>/&gt;/g;
 815         $msg =~ s/"/&quot;/g;
 816         $msg =~ s/&lt;@([^>]+)&gt;/'<@' . irc_name_to_id($c, $1) . '>'/eg;
 817         $msg =~ s/&lt;#([^>]+)&gt;/'<#' . irc_chan_to_id($c, $1) . '>'/eg;
 818
 819         foreach my $name (split(/,/, $namelist)) {
 820             if (irc_eq($name, "X")) {
 821                 my @args = split(/  */, $msg);
 822                 my $cmd = shift @args;
 823                 my $handler = $gateway_command{lc($cmd)};
 824
 825                 if (defined $handler) {
 826                     $handler->($c, @args);
 827                 } else {
 828                     irc_gateway_notice $c, "Unknown command: $cmd";
 829                 }
 830             } elsif ($name =~ /^#(.*)$/) {
 831                 my $chan = $channels_by_name{irc_lcase($1)};
 832
 833                 if (defined $chan) {
 834                     rtm_send {
 835                         type => "message", channel => $chan->{Id},
 836                         text => $msg };
 837                 } else {
 838                     irc_send_num $c, 401, [$name], "No such nick/channel";
 839                 }
 840             } elsif (irc_eq($name, $c->{Nick})) {
 841                 rtm_send_to_user $self_id, $msg;
 842             } else {
 843                 my $user = $users_by_name{irc_lcase($name)};
 844
 845                 if (defined $user) {
 846                     rtm_send_to_user $user->{Id}, $msg;
 847                 } else {
 848                     irc_send_num $c, 401, [$name], "No such nick/channel";
 849                 }
 850             }
 851         }
 852     },
 853     "PONG" => sub {
 854         shift->{PingCount} = 0;
 855     },
 856     "QUIT" => sub {
 857         my $c = shift;
 858         irc_disconnect $c, "QUIT";
 859     },
 860 );
 861
 862 sub irc_broadcast_notice {
 863     my ($msg) = @_;
 864
 865     print "NOTICE: $msg\n";
 866     foreach my $k (keys %irc_clients) {
 867         my $c = $irc_clients{$k};
 868         irc_server_notice $c, $msg if $c->{Authed};
 869     }
 870 }
 871
 872 sub irc_id_to_name {
 873     my ($c, $id) = @_;
 874     return $c->{Nick} if $id eq $self_id;
 875     my $u = $users{$id};
 876     return $u->{Name} if defined($u);
 877     return $id;
 878 }
 879
 880 sub irc_name_to_id {
 881     my ($c, $name) = @_;
 882     return $self_id if $name eq $c->{Nick};
 883     my $u = $users_by_name{$name};
 884     return $u->{Id} if defined($u);
 885     return $name;
 886 }
 887
 888 sub irc_id_to_chan {
 889     my ($c, $id) = @_;
 890     my $ch = $channels{$id};
 891     return $ch->{Name} if defined ($ch);
 892     return $id;
 893 }
 894
 895 sub irc_chan_to_id {
 896     my ($c, $chan) = @_;
 897     my $ch = $channels_by_name{$chan};
 898     return $ch->{Id} if defined($ch);
 899     return $chan;
 900 }
 901
 902 sub irc_do_message {
 903     my ($srcid, $dstname, $subtype, $text) = @_;
 904
 905     $text =~ s/\002//g;
 906     my $prefix = "";
 907     $prefix = "\002[$subtype]\002 " if defined($subtype);
 908
 909     for my $k (keys %irc_clients) {
 910         my $c = $irc_clients{$k};
 911         next unless $c->{Ready};
 912
 913         my $translate = $text;
 914         $translate =~ s/<@([^>]+)>/'<@' . irc_id_to_name($c, $1) . '>'/eg;
 915         $translate =~ s/<#([^>]+)>/'<#' . irc_id_to_chan($c, $1) . '>'/eg;
 916         $translate =~ s/&lt;/</g;
 917         $translate =~ s/&gt;/>/g;
 918         $translate =~ s/&quot;/"/g;
 919         $translate =~ s/&amp;/&/g;
 920
 921         for my $line (split(/\n/, $translate)) {
 922             irc_send_from $c, $srcid, ["PRIVMSG", $dstname], "$prefix$line";
 923         }
 924     }
 925 }
 926
 927 sub irc_privmsg {
 928     my ($id, $subtype, $msg) = @_;
 929     irc_do_message $id, $users{$id}->{Name}, $subtype, $msg;
 930 }
 931
 932 sub irc_chanmsg {
 933     my ($id, $subtype, $chid, $msg) = @_;
 934     irc_do_message $id, "#$channels{$chid}->{Name}", $subtype, $msg;
 935 }
 936
 937 sub irc_topic_change {
 938     my ($id, $chid) = @_;
 939     my $chan = $channels{$chid};
 940
 941     foreach my $k (keys %irc_clients) {
 942         my $c = $irc_clients{$k};
 943
 944         irc_send_from $c, $id, ["TOPIC", "#$chan->{Name}"], $chan->{Topic}
 945             if $c->{Ready};
 946     }
 947 }
 948
 949 sub irc_ping {
 950     my $c = shift;
 951
 952     if (++$c->{PingCount} >= 3) {
 953         irc_disconnect $c, "Ping timeout";
 954         return;
 955     }
 956
 957     irc_send_args $c, "localhost", ["PING"], time();
 958     $c->{PingTimer} = AnyEvent->timer(after => 60, cb => sub { irc_ping($c); });
 959 }
 960
 961 sub irc_line {
 962     my ($c, $fh, $line, $eol) = @_;
 963
 964     print "IRC $fh RECV: $line\n" if $config{debug_dump};
 965
 966     utf8::decode($line);
 967
 968     my $smallargs = $line;
 969     my $bigarg = undef;
 970
 971     if ($line =~ /^(.*?) :(.*)$/) {
 972         $smallargs = $1;
 973         $bigarg = $2;
 974     }
 975
 976     my @words = split /  */, $smallargs;
 977     push @words, $bigarg if defined($bigarg);
 978
 979     if (scalar(@words)) {
 980         my $cmd = shift @words;
 981         my $handler = $irc_command{uc($cmd)};
 982
 983         $handler->($c, @words) if (defined($handler));
 984     }
 985
 986     $fh->push_read(line => sub { irc_line($c, @_) });
 987 }
 988
 989 sub irc_listen {
 990     print "Start IRC listener\n";
 991     my $listen_host = $config{unix_socket} ? "unix/" : "127.0.0.1";
 992     tcp_server $listen_host,
 993                ($config{unix_socket} || $config{port} || 6667), sub {
 994         my ($fd, $host, $port) = @_;
 995
 996         my $fh;
 997         $fh = new AnyEvent::Handle
 998           fh => $fd,
 999           on_error => sub {
1000               my ($fh, $fatal, $msg) = @_;
1001               irc_disconnect $irc_clients{$fh}, "error: $msg";
1002           },
1003           on_eof => sub {
1004               my $fh = shift;
1005               irc_disconnect $irc_clients{$fh}, "EOF";
1006           };
1007
1008         print "IRC $fh Got connection from $host:$port\n";
1009
1010         my $c = { Handle => $fh };
1011         $c->{PingTimer} = AnyEvent->timer(after => 30,
1012                 cb => sub { irc_ping $c; });
1013         $c->{PingCount} = 0;
1014         $irc_clients{$fh} = $c;
1015         $fh->push_read(line => sub { irc_line($c, @_) });
1016
1017         irc_server_notice $c, "Waiting for RTM connection" if not $connected;
1018     }, sub {
1019         chmod 0600, $config{unix_socket} if $config{unix_socket};
1020     }
1021 }
1022
1023 ########################################################################
1024 # RTM client
1025 ########################################################################
1026
1027 my $rtm_client;
1028 my $rtm_con;
1029 my $rtm_msg_id = 1;
1030 my %rtm_apicall_handles;
1031 my $rtm_cooldown_timer;
1032
1033 my %rtm_mark_queue;
1034 my $rtm_mark_timer;
1035
1036 my $rtm_ping_timer;
1037 my $rtm_ping_count;
1038
1039 sub rtm_apicall {
1040     my ($method, $args, $cb) = @_;
1041     my @encode;
1042
1043     print "RTM APICALL $method ", Dumper($args) if $config{debug_dump};
1044
1045     $args->{token} = $config{slack_token};
1046
1047     foreach my $k (keys %$args) {
1048         my $ek = uri_encode($k);
1049         my $ev = uri_encode($args->{$k});
1050
1051         push @encode, "$ek=$ev";
1052     }
1053
1054     my $x;
1055     $x = http_post "https://slack.com/api/$method", join('&', @encode),
1056         headers => {
1057             "Content-Type", "application/x-www-form-urlencoded"
1058         }, sub {
1059             my ($body, $hdr) = @_;
1060             delete $rtm_apicall_handles{$x};
1061
1062             unless ($hdr->{Status} =~ /^2/) {
1063                 irc_broadcast_notice
1064                   "API HTTP error: $method: $hdr->{Status} $hdr->{Reason}";
1065                 $cb->(undef) if defined($cb);
1066                 return;
1067             }
1068
1069             my $data = decode_json $body;
1070
1071             print "RTM REPLY $method ", Dumper($data) if $config{debug_dump};
1072
1073             unless ($data->{ok}) {
1074                 irc_broadcast_notice "API error: $data->{error}";
1075                 $cb->(undef) if defined($cb);
1076                 return;
1077             }
1078
1079             $cb->($data) if defined($cb);
1080         };
1081
1082     $rtm_apicall_handles{$x} = 1;
1083 }
1084
1085 sub rtm_send {
1086     my $frame = shift;
1087
1088     $frame->{id} = $rtm_msg_id++;
1089     print "RTM SEND: ", Dumper($frame) if $config{debug_dump};
1090     $rtm_con->send(encode_json $frame);
1091 }
1092
1093 sub rtm_update_join {
1094     my ($uid, $chid) = @_;
1095     my $chan = $channels{$chid};
1096     my $user = $users{$uid};
1097
1098     if (!$chan->{Members}->{$uid}) {
1099         $chan->{Members}->{$uid} = 1;
1100         $user->{Channels}->{$chid} = 1;
1101         return 1;
1102     }
1103
1104     return undef;
1105 }
1106
1107 sub rtm_update_part {
1108     my ($uid, $chid) = @_;
1109     my $chan = $channels{$chid};
1110     my $user = $users{$uid};
1111
1112     if ($chan->{Members}->{$uid}) {
1113         delete $channels{$chid}->{Members}->{$uid};
1114         delete $users{$uid}->{Channels}->{$chid};
1115         return 1;
1116     }
1117
1118     return undef;
1119 }
1120
1121 sub rtm_update_user {
1122     my $c = shift;
1123     my $user;
1124
1125     if (exists $users{$c->{id}}) {
1126         $user = $users{$c->{id}};
1127         my $oldname = $user->{Name};
1128         delete $users_by_name{irc_lcase($oldname)};
1129         my $newname = irc_pick_name($c->{name}, \%users_by_name);
1130
1131         $user->{Realname} = $c->{real_name} // $c->{name};
1132
1133         irc_broadcast_nick $c->{id}, $newname
1134             if $oldname ne $newname;
1135
1136         $user->{Name} = $newname;
1137         $user->{Presence} = $c->{presence} // 'active';
1138         $users_by_name{$newname} = $user;
1139     } else {
1140         my $name = irc_pick_name($c->{name}, \%users_by_name);
1141         $user = {
1142             Id => $c->{id},
1143             Name => $name,
1144             Channels => {},
1145             Realname => $c->{real_name} // $c->{name},
1146             TxQueue => [],
1147             Presence => $c->{presence} // 'active'
1148         };
1149
1150         $users{$c->{id}} = $user;
1151         $users_by_name{$name} = $user;
1152     }
1153
1154     $user->{Realname} = "" unless defined($user->{Realname});
1155 }
1156
1157 sub rtm_record_unknown_uid {
1158     my $uid = shift;
1159
1160     unless (exists $users{$uid}) {
1161         # Temporary name
1162         my $name = irc_pick_name($uid, \%users_by_name);
1163
1164         my $u = {
1165             Id => $uid,
1166             Name => $name,
1167             Channels => {},
1168             Realname => "",
1169             TxQueue => []
1170         };
1171
1172         $users{$uid} = $u;
1173         $users_by_name{irc_lcase($name)} = $u;
1174
1175         rtm_apicall "users.info", { user => $uid }, sub {
1176             my $data = shift;
1177
1178             rtm_update_user $data->{user} if defined $data;
1179         };
1180     }
1181 }
1182
1183 sub rtm_update_channel {
1184     my ($type, $c) = @_;
1185
1186     my $id = $c->{id};
1187     my $mhash = {};
1188     my $name = $c->{name};
1189
1190     $name = "+$name" if $type eq "G";
1191
1192     # Cross-reference users/channels
1193     foreach my $u (@{$c->{members}}) {
1194         rtm_record_unknown_uid $u;
1195         # Filter ourselves out of the membership list if this is a
1196         # closed group chat.
1197         next if $type eq 'G' && $u eq $self_id && !$c->{is_open};
1198         $mhash->{$u} = 1;
1199         $users{$u}->{Channels}->{$id} = 1;
1200     }
1201
1202     if (exists $channels{$id}) {
1203         my $chan = $channels{$id};
1204         $chan->{Members} = $mhash;
1205         $chan->{Topic} = $c->{topic}->{value};
1206         $chan->{Type} = $type;
1207     } else {
1208         my $name = irc_pick_name($name, \%channels_by_name);
1209         my $chan = {
1210             Id => $c->{id},
1211             Members => $mhash,
1212             Name => $name,
1213             Type => $type,
1214             Topic => $c->{topic}->{value}
1215         };
1216
1217         $channels{$c->{id}} = $chan;
1218         $channels_by_name{irc_lcase($name)} = $chan;
1219     }
1220 }
1221
1222 sub rtm_delete_channel {
1223     my $chid = shift;
1224     my $chan = $channels{$chid};
1225     return unless defined $chan;
1226
1227     foreach ($chan->{Members}) {
1228         my $user = $users{$_};
1229
1230         delete $user->{Channels}->{$chid};
1231     }
1232
1233     delete $channels_by_name{irc_lcase($chan->{Name})};
1234     delete $channels{$chid};
1235 }
1236
1237 sub rtm_mark_channel {
1238     my ($chid, $ts) = @_;
1239
1240     $rtm_mark_queue{$chid} = $ts;
1241
1242     unless (defined $rtm_mark_timer) {
1243         $rtm_mark_timer = AnyEvent->timer(after => 5, cb => sub {
1244             for my $chid (keys %rtm_mark_queue ) {
1245                 rtm_apicall "channels.mark", {
1246                     channel => $chid,
1247                     ts => $rtm_mark_queue{$chid}
1248                 };
1249             }
1250             %rtm_mark_queue = ();
1251             undef $rtm_mark_timer;
1252         });
1253     }
1254 }
1255
1256 my %rtm_command = (
1257     "presence_change" => sub {
1258         my $msg = shift;
1259         my $user = $users{$msg->{user}};
1260
1261         if (defined $user) {
1262             my $old = $user->{Presence};
1263             $user->{Presence} = $msg->{presence} if defined $user;
1264             irc_broadcast_away if
1265               $msg->{user} eq $self_id and $old ne $msg->{presence};
1266         }
1267     },
1268     "manual_presence_change" => sub {
1269         my $msg = shift;
1270         my $user = $users{$self_id};
1271         my $old = $user->{Presence};
1272
1273         $user->{Presence} = $msg->{presence};
1274         irc_broadcast_away if $old ne $msg->{presence};
1275     },
1276     "im_open" => sub {
1277         my $msg = shift;
1278         rtm_record_unknown_uid $msg->{user};
1279
1280         my $u = $users{$msg->{user}};
1281         $u->{DMId} = $msg->{channel};
1282         $users_by_dmid{$msg->{channel}} = $u;
1283
1284         foreach my $msg (@{$u->{TxQueue}}) {
1285             rtm_send { type => "message",
1286                 channel => $u->{DMId}, text => $msg };
1287         }
1288
1289         $u->{TxQueue} = [];
1290     },
1291     "im_close" => sub {
1292         my $msg = shift;
1293         my $u = $users_by_dmid{$msg->{channel}};
1294         return unless defined($u);
1295
1296         delete $u->{DMId};
1297         delete $users_by_dmid{$msg->{channel}};
1298     },
1299     "group_joined" => sub {
1300         my $msg = shift;
1301
1302         rtm_update_channel "G", $msg->{channel};
1303         irc_broadcast_join $self_id, $msg->{channel}->{id};
1304     },
1305     "group_left" => sub {
1306         my $msg = shift;
1307
1308         irc_broadcast_part $self_id, $msg->{channel}
1309           if rtm_update_part $self_id, $msg->{channel};
1310     },
1311     "group_archive" => sub {
1312         my $msg = shift;
1313
1314         irc_broadcast_part $self_id, $msg->{channel}
1315           if rtm_update_part $self_id, $msg->{channel};
1316         rtm_delete_channel $msg->{channel};
1317     },
1318     "channel_joined" => sub {
1319         my $msg = shift;
1320
1321         rtm_update_channel "C", $msg->{channel};
1322         irc_broadcast_join $self_id, $msg->{channel}->{id};
1323     },
1324     "channel_left" => sub {
1325         my $msg = shift;
1326
1327         irc_broadcast_part $self_id, $msg->{channel}
1328           if rtm_update_part $self_id, $msg->{channel};
1329     },
1330     "channel_archive" => sub {
1331         my $msg = shift;
1332
1333         irc_broadcast_part $self_id, $msg->{channel}
1334           if rtm_update_part $self_id, $msg->{channel};
1335         rtm_delete_channel $msg->{channel};
1336     },
1337     "member_joined_channel" => sub {
1338         my $msg = shift;
1339
1340         rtm_record_unknown_uid $msg->{user};
1341         irc_broadcast_join $msg->{user}, $msg->{channel}
1342           if rtm_update_join($msg->{user}, $msg->{channel});
1343     },
1344     "member_left_channel" => sub {
1345         my $msg = shift;
1346
1347         irc_broadcast_part $msg->{user}, $msg->{channel}
1348           if rtm_update_part($msg->{user}, $msg->{channel});
1349     },
1350     "pong" => sub {
1351         $rtm_ping_count = 0;
1352     },
1353     "message" => sub {
1354         my $msg = shift;
1355         my $chan = $channels{$msg->{channel}};
1356         my $subtype = $msg->{subtype} || "";
1357         my $uid = $msg->{user} || $msg->{comment}->{user} || $msg->{bot_id};
1358         my $text = $msg->{text} // '';
1359
1360         if (defined($msg->{attachments})) {
1361             my $attext = join '\n', map {
1362                 ($_->{title} or "")
1363                   . " " . ($_->{text} or "")
1364                   . " " . ($_->{title_link} or "") } @{$msg->{attachments}};
1365             $text .= "\n" unless length($text);
1366             $text .= $attext;
1367         }
1368
1369         if (defined($chan)) {
1370             if ($subtype eq "channel_topic" or $subtype eq "group_topic") {
1371                 $chan->{Topic} = $msg->{topic};
1372                 irc_topic_change $uid, $chan->{Id};
1373             } else {
1374                 irc_chanmsg $uid, $msg->{subtype}, $chan->{Id}, $text;
1375             }
1376             rtm_mark_channel $chan->{Id}, $msg->{ts};
1377         } else {
1378             irc_privmsg $uid, $msg->{subtype}, $text;
1379         }
1380
1381         if ($subtype eq "file_share") {
1382             my $fid = $msg->{file}->{id};
1383             rtm_apicall "files.info", { file => $fid }, sub {
1384                 my $data = shift;
1385                 return unless defined $data;
1386
1387                 my $body = $data->{content};
1388                 return unless length($body) <= 65536;
1389
1390                 if (defined $chan) {
1391                     irc_chanmsg $uid, ">$fid", $chan->{Id}, $body;
1392                 } else {
1393                     irc_privmsg $uid, ">$fid", $body;
1394                 }
1395             };
1396         }
1397     },
1398 );
1399
1400 sub rtm_send_to_user {
1401     my ($id, $msg) = @_;
1402     my $u = $users{$id};
1403
1404     if (defined($u->{DMId}) && length($u->{DMId})) {
1405         rtm_send { type => "message",
1406                 channel => $u->{DMId}, text => $msg };
1407         return;
1408     }
1409
1410     push @{$u->{TxQueue}}, $msg;
1411
1412     if (!defined($u->{DMId})) {
1413         rtm_apicall "im.open", { user => $u->{Id} }, sub {
1414             my $result = shift;
1415             unless (defined $result) {
1416                 delete $u->{DMId};
1417                 foreach my $m (@{$u->{TxQueue}}) {
1418                     irc_broadcast_notice "Failed to send to $u->{Name}: $m";
1419                 }
1420                 $u->{TxQueue} = [];
1421             }
1422         };
1423
1424         $u->{DMId} = "";
1425     }
1426 }
1427
1428 sub rtm_start;
1429
1430 sub rtm_cooldown {
1431     return if defined($rtm_cooldown_timer);
1432     print "Waiting before reinitiating RTM\n";
1433     $rtm_cooldown_timer = AnyEvent->timer(after => 5, cb => sub {
1434         undef $rtm_cooldown_timer;
1435         rtm_start;
1436     });
1437 };
1438
1439 sub rtm_destroy {
1440     my $msg = shift;
1441     return unless defined($rtm_con);
1442
1443     irc_broadcast_notice $msg;
1444
1445     $connected = 0;
1446     undef $self_id;
1447     %channels = ();
1448     %channels_by_name = ();
1449     %users = ();
1450     %users_by_name = ();
1451     %users_by_dmid = ();
1452
1453     %rtm_apicall_handles = (); # cancel outstanding requests
1454     %rtm_mark_queue = ();
1455     undef $rtm_mark_timer;
1456     undef $rtm_ping_timer;
1457     $rtm_con->close;
1458     undef $rtm_con;
1459     undef $rtm_client;
1460
1461     irc_disconnect_all;
1462     rtm_cooldown;
1463 }
1464
1465 sub rtm_ping {
1466     if (++$rtm_ping_count >= 2) {
1467         rtm_destroy "RTM ping timeout";
1468         return;
1469     }
1470
1471     rtm_send { type => "ping" };
1472     $rtm_ping_timer = AnyEvent->timer(after => 60, cb => \&rtm_ping);
1473 }
1474
1475 sub rtm_start_ws {
1476     my $url = shift;
1477
1478     return if defined($rtm_client);
1479     $rtm_client = AnyEvent::WebSocket::Client->new;
1480
1481     print "WSS URL: $url\n" if $config{debug_dump};
1482     $rtm_client->connect($url)->cb(sub {
1483         $rtm_con = eval { shift->recv; };
1484         if ($@) {
1485             irc_broadcast_notice "WSS connection failed: $@\n";
1486             undef $rtm_client;
1487             rtm_cooldown;
1488         }
1489
1490         print "WSS connected\n";
1491         $rtm_msg_id = 1;
1492         $rtm_ping_count = 0;
1493         $connected = 1;
1494         irc_check_welcome_all;
1495
1496         $rtm_ping_timer = AnyEvent->timer(after => 60, cb => \&rtm_ping);
1497
1498         $rtm_con->on(each_message => sub {
1499             eval {
1500                 shift;
1501                 my $msg = decode_json shift->{body};
1502
1503                 print "RTM RECV: ", Dumper($msg) if $config{debug_dump};
1504                 irc_broadcast_notice "RTM error: $msg->{error}->{msg}"
1505                     if $msg->{error};
1506
1507                 if (defined $msg->{type}) {
1508                     my $handler = $rtm_command{$msg->{type}};
1509                     $handler->($msg) if defined($handler);
1510                 }
1511             };
1512             print "Error in message handler: $@" if $@;
1513         });
1514
1515         $rtm_con->on(finish => sub {
1516             eval {
1517                 my ($con) = @_;
1518
1519                 if (defined $con->close_error) {
1520                     rtm_destroy "RTM connection error: $con->close_error";
1521                 } elsif (defined $con->close_reason) {
1522                     rtm_destroy "RTM connection closed: $con->close_reason";
1523                 } else {
1524                     rtm_destroy "RTM connection finished";
1525                 }
1526             };
1527             print "Error in finish handler: $@" if $@;
1528         });
1529     });
1530 };
1531
1532 sub rtm_start {
1533     print "Requesting RTM connection\n";
1534     rtm_apicall "rtm.start", {}, sub {
1535         my $data = shift;
1536
1537         unless (defined($data)) {
1538             rtm_cooldown;
1539             return;
1540         }
1541
1542         $self_id = $data->{self}->{id};
1543
1544         foreach my $c (@{$data->{users}}) {
1545             rtm_update_user $c;
1546         }
1547
1548         foreach my $c (@{$data->{ims}}) {
1549             my $u = $users{$c->{user}};
1550
1551             $u->{DMId} = $c->{id};
1552             $users_by_dmid{$c->{id}} = $u;
1553         }
1554
1555         foreach my $c (@{$data->{channels}}) {
1556             rtm_update_channel "C", $c unless $c->{is_archived};
1557         }
1558
1559         foreach my $c (@{$data->{bots}}) {
1560             rtm_update_user $c;
1561             my $n = $c->{id};
1562         }
1563
1564         foreach my $c (@{$data->{groups}}) {
1565             rtm_update_channel "G", $c unless $c->{is_archived};
1566         }
1567
1568         rtm_start_ws $data->{url};
1569     };
1570 };
1571
1572 ########################################################################
1573 # RTM kick-off
1574 ########################################################################
1575
1576 my $cfgfile = shift || die "You must specify a config file";
1577 open(my $cfg, $cfgfile) || die "Can't open $cfgfile";
1578 foreach (<$cfg>) {
1579     chomp;
1580     $config{$1} = $2 if /^([-_0-9a-zA-Z]+)=(.*)$/;
1581 }
1582 close($cfg);
1583
1584 rtm_start;
1585 irc_listen;
1586 AnyEvent->condvar->recv;