slirc.pl

   1 #!/usr/bin/perl -w
   2 # slirc.pl: local Slack IRC gateway
   3 # Copyright (C) 2017-2019 Daniel Beer <dlbeer@gmail.com>
   4 #
   5 # Permission to use, copy, modify, and/or distribute this software for any
   6 # purpose with or without fee is hereby granted, provided that the above
   7 # copyright notice and this permission notice appear in all copies.
   8 #
   9 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  10 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  11 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  12 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  13 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  14 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  15 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  16 #
  17 # To run, create a configuration file with the following content:
  18 #
  19 #     slack_token=<legacy API token>
  20 #     password=<password of your choice>
  21 #     port=<port>
  22 #
  23 # Then run ./slirc.pl <config-file>. Connect to the chosen port on
  24 # 127.0.0.1 with your chosen password.
  25 #
  26 # Updated 2018-05-15 to add support for listening on Unix domain sockets
  27 # by Colin Watson <cjwatson@chiark.greenend.org.uk>. To use this feature
  28 # with an IRC client supporting Unix domain connections, add the line
  29 # "unix_socket=<path>" to the config file.
  30 #
  31 # Updated 2019-02-18:
  32 # - HTML entities are now escaped/unescaped properly
  33 # - Channel IDs are translated with the correct sigil
  34 # - You can now close accumulated group chats. This is mapped to
  35 #   JOIN/PART (the behaviour of JOIN/PART for public channels is
  36 #   unaffected)
  37 # - IRC-side PING checks are now more lenient, to work around bugs in
  38 #   some IRC clients
  39 # - Added X commands for debug dumps and dynamically switching protocol
  40 #   debug on/off
  41 #
  42 # Updated 2019-05-08 based on changes from Neia Finch to improve
  43 # support for bots.
  44
  45 use strict;
  46 use warnings;
  47 use utf8;
  48
  49 use AnyEvent;
  50 use AnyEvent::HTTP;
  51 use AnyEvent::Socket;
  52 use AnyEvent::WebSocket::Client;
  53 use URI::Encode qw(uri_encode);
  54 use Data::Dumper;
  55 use Time::localtime;
  56 use Digest::SHA qw(sha256);
  57 use JSON;
  58
  59 my $VERSION = "20190225";
  60 my $start_time = time();
  61 my %config;
  62
  63 $| = 1;
  64
  65 ########################################################################
  66 # Global chat state
  67 ########################################################################
  68
  69 my $connected;                  # Is the RTM connection ready?
  70 my $self_id;                    # Slack ID of our own user, or undef
  71
  72 my %channels;                   # Slack ID -> channel hash ref
  73 my %channels_by_name;           # irc_lcase -> channel hash ref
  74 # Properties:
  75 # - Id: Slack ID
  76 # - Members: Slack ID set
  77 # - Name: text (IRC name)
  78 # - Topic: text
  79
  80 my %users;                      # Slack ID -> user hash ref
  81 my %users_by_name;              # irc_lcase -> user hash ref
  82 my %users_by_dmid;              # Slack DMID -> user hash ref
  83 # Properties:
  84 # - Id: Slack ID
  85 # - Name: text (IRC name)
  86 # - Channels: Slack ID set
  87 # - Realname: text
  88 # - DMId: DM session ID (may be undefined, or blank if open in progress)
  89 # - TxQueue: messages awaiting transmission if no DM open
  90
  91 ########################################################################
  92 # IRC names
  93 ########################################################################
  94
  95 # Canonicalize an IRC name
  96 sub irc_lcase {
  97     my $name = lc(shift);
  98
  99     $name =~ s/\[/{/g;
 100     $name =~ s/]/}/g;
 101     $name =~ s/\|/\\/g;
 102     $name =~ s/\^/~/g;
 103
 104     return $name;
 105 }
 106
 107 # Compare two names
 108 sub irc_eq {
 109     my ($a, $b) = @_;
 110
 111     return irc_lcase($a) eq irc_lcase($b);
 112 }
 113
 114 # Choose an unused valid name with reference to the hash
 115 sub irc_pick_name {
 116     my ($name, $hash) = @_;
 117
 118     $name =~ s/[#,<>!\0\r\n: ]/_/g;
 119
 120     return $name if length($name) && irc_lcase($name) ne "x" &&
 121         !defined($hash->{irc_lcase($name)});
 122
 123     my $i = 1;
 124
 125     for (;;) {
 126         my $prop = "$name$i";
 127
 128         return $prop unless defined($hash->{irc_lcase($prop)});
 129         $i++;
 130     }
 131 }
 132
 133 ########################################################################
 134 # IRC server
 135 ########################################################################
 136
 137 # Forward decls to RTM subsystem
 138 sub rtm_send;
 139 sub rtm_send_to_user;
 140 sub rtm_apicall;
 141 sub rtm_download;
 142 sub rtm_destroy;
 143 sub rtm_update_join;
 144 sub rtm_update_part;
 145
 146 my %irc_clients;
 147
 148 sub irc_send_args {
 149     my ($c, $source, $short, $long) = @_;
 150
 151     $source =~ s/[\t\r\n\0 ]//g;
 152     $source =~ s/^://g;
 153     my @arg = (":$source");
 154
 155     for my $a (@$short) {
 156         $a =~ s/[\t\r\n\0 ]//g;
 157         $a =~ s/^://g;
 158         utf8::encode($a);
 159         $a = "*" unless length($a);
 160         push @arg, $a;
 161     }
 162
 163     if (defined($long)) {
 164         $long =~ s/[\r\n\0]/ /g;
 165         utf8::encode($long);
 166         push @arg, ":$long";
 167     }
 168
 169     my $line = join(' ', @arg);
 170     print "IRC $c->{Handle} SEND: $line\n" if $config{debug_dump};
 171     $c->{Handle}->push_write("$line\r\n");
 172 }
 173
 174 sub irc_send_num {
 175     my ($c, $num, $short, $long) = @_;
 176     my $dst = $c->{Nick};
 177
 178     $dst = "*" unless defined($c->{Nick});
 179     irc_send_args $c, "localhost",
 180         [sprintf("%03d", $num), $dst, @$short], $long;
 181 }
 182
 183 sub irc_send_from {
 184     my ($c, $uid, $short, $long) = @_;
 185     my $user = $users{$uid};
 186     my $nick = $uid eq $self_id ? $c->{Nick} : $user->{Name};
 187
 188     irc_send_args $c, "$nick!$user->{Id}\@localhost", $short, $long;
 189 }
 190
 191 sub irc_disconnect {
 192     my ($c, $msg) = @_;
 193
 194     print "IRC $c->{Handle} DISCONNECT: $msg\n";
 195     delete $irc_clients{$c->{Handle}};
 196     $c->{Handle}->destroy;
 197 }
 198
 199 sub irc_disconnect_all {
 200     print "IRC: disconnect all\n";
 201     foreach my $k (keys %irc_clients) {
 202         $irc_clients{$k}->{Handle}->destroy;
 203     }
 204     %irc_clients = ();
 205 }
 206
 207 sub irc_send_names {
 208     my ($c, $chan) = @_;
 209     my $i = 0;
 210     my @ulist = keys %{$chan->{Members}};
 211
 212     while ($i < @ulist) {
 213         my $n = @ulist - $i;
 214         $n = 8 if $n > 8;
 215         my $chunk = join(' ', map {
 216             $_ eq $self_id ? $c->{Nick} : $users{$_}->{Name}
 217         } @ulist[$i .. ($i + $n - 1)]);
 218         irc_send_num $c, 353, ['@', "#$chan->{Name}"], $chunk;
 219         $i += $n;
 220     }
 221
 222     irc_send_num $c, 366, ["#$chan->{Name}"], "End of /NAMES list";
 223 }
 224
 225 sub irc_server_notice {
 226     my ($c, $msg) = @_;
 227     my $nick = $c->{Nick};
 228
 229     $nick = "*" unless defined($nick);
 230     irc_send_args $c, "localhost", ["NOTICE", $nick], $msg;
 231 }
 232
 233 sub irc_gateway_notice {
 234     my ($c, $msg) = @_;
 235     my $nick = $c->{Nick};
 236
 237     $nick = "*" unless defined($nick);
 238     irc_send_args $c, "X!X\@localhost", ["NOTICE", $nick], $msg;
 239 }
 240
 241 sub irc_notify_away {
 242     my $c = shift;
 243     my $user = $users{$self_id};
 244     my ($num, $msg);
 245
 246     if ($user->{Presence} eq 'away') {
 247         $num = 306;
 248         $msg = "You have been marked as being away";
 249     } else {
 250         $num = 305;
 251         $msg = "You are no longer marked as being away";
 252     }
 253
 254     irc_send_num $c, $num, [], $msg if $c->{Ready};
 255 }
 256
 257 sub irc_broadcast_away {
 258     for my $k (keys %irc_clients) {
 259         my $c = $irc_clients{$k};
 260         irc_notify_away $c if $c->{Ready};
 261     }
 262 }
 263
 264 sub irc_send_motd {
 265     my $c = shift;
 266     my @banner =
 267       (
 268        '     _ _                  _',
 269        ' ___| (_)_ __ ___   _ __ | |',
 270        '/ __| | | \'__/ __| | \'_ \| |',
 271        '\__ \ | | | | (__ _| |_) | |',
 272        '|___/_|_|_|  \___(_) .__/|_|',
 273        '                   |_|',
 274        'slirc.pl, Copyright (C) 2017-2019 Daniel Beer <dlbeer@gmail.com>'
 275       );
 276
 277     for my $x (@banner) {
 278         irc_send_num $c, 372, [], $x;
 279     }
 280     irc_send_num $c, 376, [], "End of /MOTD command";
 281 }
 282
 283 sub irc_check_welcome {
 284     my $c = shift;
 285
 286     if (defined $c->{Nick} && defined $c->{User} &&
 287         (!$config{password} || defined $c->{Password}) &&
 288         !$c->{Authed}) {
 289         if (!$config{password} ||
 290             sha256($c->{Password}) eq sha256($config{password})) {
 291             $c->{Authed} = 1;
 292         } else {
 293             irc_server_notice $c, "Incorrect password";
 294             irc_disconnect $c, "Incorrect password";
 295             return;
 296         }
 297     }
 298
 299     return unless $c->{Authed} && !$c->{Ready} && $connected;
 300
 301     my $u = $users_by_name{irc_lcase($c->{Nick})};
 302     if (defined($u) && ($u->{Id} ne $self_id)) {
 303         irc_server_notice $c, "Nick already in use";
 304         irc_disconnect $c, "Nick already in use";
 305         return;
 306     }
 307
 308     my $lt = localtime($start_time);
 309
 310     irc_send_num $c, 001, [], "slirc.pl IRC-to-Slack gateway";
 311     irc_send_num $c, 002, [], "This is slirc.pl version $VERSION";
 312     irc_send_num $c, 003, [], "Server started " . ctime($start_time);
 313     irc_send_motd $c;
 314     $c->{Ready} = 1;
 315
 316     my $user = $users{$self_id};
 317
 318     for my $k (keys %{$user->{Channels}}) {
 319         my $chan = $channels{$k};
 320         irc_send_from $c, $self_id, ["JOIN", "#$chan->{Name}"];
 321         irc_send_num $c, 332, ["#$chan->{Name}"], $chan->{"Topic"};
 322         irc_send_names $c, $chan;
 323     }
 324
 325     irc_notify_away $c;
 326 }
 327
 328 sub irc_check_welcome_all {
 329     foreach my $k (keys %irc_clients) {
 330         irc_check_welcome $irc_clients{$k};
 331     }
 332 }
 333
 334 sub irc_broadcast_nick {
 335     my ($id, $newname) = @_;
 336     return if $id eq $self_id;
 337
 338     for my $k (keys %irc_clients) {
 339         my $c = $irc_clients{$k};
 340         irc_send_from $c, $id, ["NICK", $newname] if $c->{Ready};
 341     }
 342 }
 343
 344 sub irc_broadcast_join {
 345     my ($uid, $chid) = @_;
 346     my $chan = $channels{$chid};
 347
 348     for my $k (keys %irc_clients) {
 349         my $c = $irc_clients{$k};
 350         next unless $c->{Ready};
 351
 352         if ($uid eq $self_id) {
 353             irc_send_from $c, $self_id, ["JOIN", "#$chan->{Name}"];
 354             irc_send_num $c, 332, ["#$chan->{Name}"], $chan->{Topic};
 355             irc_send_names $c, $chan;
 356         } else {
 357             irc_send_from $c, $uid, ["JOIN", "#$chan->{Name}"];
 358         }
 359     }
 360 }
 361
 362 sub irc_broadcast_part {
 363     my ($uid, $chid) = @_;
 364     my $chan = $channels{$chid};
 365
 366     for my $k (keys %irc_clients) {
 367         my $c = $irc_clients{$k};
 368         next unless $c->{Ready};
 369         irc_send_from $c, $uid, ["PART", "#$chan->{Name}"];
 370     }
 371 }
 372
 373 sub irc_send_who {
 374     my ($c, $chname, $u) = @_;
 375
 376     my $user = $users{$u};
 377     my $nick = $u eq $self_id ? $c->{Nick} : $user->{Name};
 378     my $here = $user->{Presence} eq 'away' ? 'G' : 'H';
 379
 380     irc_send_num $c, 352, [$chname, $user->{Id}, "localhost", "localhost",
 381                            $nick, $here], "0 $user->{Realname}";
 382 }
 383
 384 sub irc_send_whois {
 385     my ($c, $uid) = @_;
 386     my $u = $users{$uid};
 387     my $nick = $uid eq $self_id ? $c->{Nick} : $u->{Name};
 388
 389     irc_send_num $c, 311,
 390         [$nick, $u->{Id}, "localhost", "*"], $u->{Realname};
 391     irc_send_num $c, 312, [$nick, "localhost"], "slirc.pl";
 392     my $clist = join(' ', map { "#" . $channels{$_}->{Name} }
 393                           keys %{$u->{Channels}});
 394     irc_send_num $c, 319, [$nick], $clist;
 395     irc_send_num $c, 301, [$nick], "away" if $u->{Presence} eq 'away';
 396 }
 397
 398 sub irc_invite_or_kick {
 399     my ($c, $action, $name, $chname) = @_;
 400
 401     $chname =~ s/^#//;
 402     my $chan = $channels_by_name{irc_lcase($chname)};
 403
 404     unless (defined $chan) {
 405         irc_send_num $c, 401, ["#$chname"], "No such nick/channel";
 406         return;
 407     }
 408
 409     my $what = $chan->{Type} eq "C" ? "channels" : "groups";
 410
 411     foreach (split(/,/, $name)) {
 412         my $user = $users_by_name{irc_lcase($_)};
 413
 414         if (defined $user) {
 415             rtm_apicall "$what.$action", { user => $user->{Id},
 416                                            channel => $chan->{Id} };
 417         } else {
 418             irc_send_num $c, 401, [$user], "No such nick/channel";
 419         }
 420     }
 421 }
 422
 423 my %gateway_command = (
 424     "debug_dump_state" => sub {
 425         my $c = shift;
 426         irc_gateway_notice $c, "Dumping debug state on stdout";
 427         print Dumper({ "connected" => $connected,
 428                        "self_id", => $self_id,
 429                        "%channels" => \%channels,
 430                        "%channels_by_name" => \%channels_by_name,
 431                        "users" => \%users,
 432                        "users_by_name" => \%users_by_name,
 433                        "users_by_dmid" => \%users_by_dmid
 434                      });
 435     },
 436     "debug_dump" => sub {
 437         my ($c, $arg) = @_;
 438         $config{debug_dump} = $arg ? 1 : 0 if defined $arg;
 439         irc_gateway_notice $c, "Protocol debug is " .
 440           ($config{debug_dump} ? "on" : "off");
 441     },
 442     "newgroup" => sub {
 443         my ($c, $name) = @_;
 444         unless (defined($name)) {
 445             irc_gateway_notice $c, "Syntax: newgroup <name>";
 446             return;
 447         }
 448         $name =~ s/^#//;
 449         irc_gateway_notice $c, "Creating group $name";
 450         rtm_apicall "groups.create", { name => $name };
 451     },
 452     "newchan" => sub {
 453         my ($c, $name) = @_;
 454         unless (defined($name)) {
 455             irc_gateway_notice $c, "Syntax: newchan <name>";
 456             return;
 457         }
 458         $name =~ s/^#//;
 459         irc_gateway_notice $c, "Creating channel $name";
 460         rtm_apicall "channels.create", { name => $name };
 461     },
 462     "archive" => sub{
 463         my ($c, $name) = @_;
 464         unless (defined($name)) {
 465             irc_gateway_notice $c, "Syntax: archive <name>";
 466             return;
 467         }
 468         $name =~ s/^#//;
 469         my $g = $channels_by_name{irc_lcase($name)};
 470         my $what = $g->{Type} eq "C" ? "channels" : "groups";
 471         if (defined $g) {
 472             irc_gateway_notice $c, "Archiving $name";
 473             rtm_apicall "$what.archive", { channel => $g->{Id} };
 474         } else {
 475             irc_gateway_notice $c, "No such channel: $name";
 476         }
 477     },
 478     "close" => sub{
 479         my ($c, $name) = @_;
 480         unless (defined($name)) {
 481             irc_gateway_notice $c, "Syntax: close <name>";
 482             return;
 483         }
 484
 485         $name =~ s/^#//;
 486         my $g = $channels_by_name{irc_lcase($name)};
 487         my $what = $g->{Type} eq "C" ? "channels" : "groups";
 488         if (defined $g) {
 489             irc_gateway_notice $c, "Closing $name";
 490             rtm_apicall "$what.close", { channel => $g->{Id} };
 491         } else {
 492             irc_gateway_notice $c, "No such channel: $name";
 493         }
 494     },
 495     "cat" => sub {
 496         my ($c, $fileid) = @_;
 497         unless (defined($fileid)) {
 498             irc_gateway_notice $c, "Syntax: cat <fileid> <filename>";
 499             return;
 500         }
 501
 502         rtm_apicall "files.info", { file => $fileid }, sub {
 503             my $data = shift;
 504             return unless defined $data;
 505
 506             my $body = $data->{content};
 507
 508             if (length($body) > 65536) {
 509                 irc_gateway_notice $c, "File too big";
 510             } else {
 511                 irc_gateway_notice $c, "---- BEGIN $fileid ----";
 512                 foreach (split(/\n/, $body)) {
 513                     irc_gateway_notice $c, "$_";
 514                 }
 515                 irc_gateway_notice $c, "---- END $fileid ----";
 516             }
 517         };
 518     },
 519     "disconnect" => sub {
 520         my ($c) = @_;
 521         irc_gateway_notice $c, "Disconnecting";
 522         rtm_destroy "User disconnection request";
 523     },
 524     "delim" => sub {
 525         my ($c, $nick) = @_;
 526         unless (defined($nick)) {
 527             irc_gateway_notice $c, "Syntax: delim <name>";
 528             return;
 529         }
 530         my $user;
 531
 532         if ($nick eq $c->{Nick}) {
 533             $user = $users{$self_id};
 534         } else {
 535             $user = $users_by_name{irc_lcase($nick)};
 536             $user = undef if $user->{Id} eq $self_id;
 537         }
 538
 539         unless (defined($user)) {
 540             irc_gateway_notice $c, "No such nick: $nick";
 541             return;
 542         }
 543
 544         unless (defined $user->{DMId}) {
 545             irc_gateway_notice $c, "DM already closed for $nick";
 546             return;
 547         }
 548
 549         irc_gateway_notice $c, "Closing DM for $nick";
 550         rtm_apicall "im.close", { channel => $user->{DMId} };
 551     },
 552 );
 553
 554 my %irc_command = (
 555     "NICK" => sub {
 556         my ($c, $newnick) = @_;
 557         return unless defined($newnick);
 558
 559         if (defined $c->{Nick}) {
 560             my $u = $users_by_name{irc_lcase($newnick)};
 561             if (defined($u) && ($u->{Id} ne $self_id)) {
 562                 irc_send_num $c, 433, [$newnick], "Nickname is already in use";
 563             } else {
 564                 irc_send_from $c, $self_id, ["NICK"], $newnick;
 565                 $c->{Nick} = $newnick;
 566             }
 567         } else {
 568             $c->{Nick} = $newnick;
 569             irc_check_welcome $c;
 570         }
 571     },
 572     "PASS" => sub {
 573         my ($c, $pass) = @_;
 574
 575         $c->{Password} = $pass;
 576         irc_check_welcome $c;
 577     },
 578     "USER" => sub {
 579         my ($c, @arg) = @_;
 580         return unless scalar(@arg) >= 4;
 581
 582         $c->{User} = $arg[0];
 583         $c->{Realname} = $arg[3];
 584         irc_check_welcome $c;
 585     },
 586     "AWAY" => sub {
 587         my ($c, $msg) = @_;
 588         return unless $c->{Ready};
 589         my $presence = defined $msg ? "away" : "auto";
 590         rtm_apicall "users.setPresence", { presence => $presence };
 591     },
 592     "PING" => sub {
 593         my ($c, $reply) = @_;
 594         $reply = "" unless defined($reply);
 595         irc_send_args $c, "localhost", ["PONG"], $reply;
 596     },
 597     "INVITE" => sub {
 598         my ($c, $name, $chname) = @_;
 599         return unless $c->{Ready};
 600         irc_invite_or_kick $c, "invite", $name, $chname;
 601     },
 602     "KICK" => sub {
 603         my ($c, $name, $chname) = @_;
 604         return unless $c->{Ready};
 605         irc_invite_or_kick $c, "kick", $name, $chname;
 606     },
 607     "JOIN" => sub {
 608         my ($c, $name) = @_;
 609         return unless $c->{Ready};
 610         return unless defined($name);
 611
 612         foreach my $n (split(/,/, $name)) {
 613             $n =~ s/^#//;
 614             my $chan = $channels_by_name{irc_lcase($n)};
 615             if (not defined $chan) {
 616                 irc_send_num $c, 401, ["#$n"], "No such nick/channel";
 617             } elsif ($chan->{Members}->{$self_id}) {
 618                 # Already joined
 619             } elsif ($chan->{Type} eq "G") {
 620                 rtm_apicall "groups.open", { channel => $chan->{Id} };
 621                 irc_broadcast_join $self_id, $chan->{Id}
 622                   if rtm_update_join $self_id, $chan->{Id};
 623             } else {
 624                 rtm_apicall "channels.join", { channel => $chan->{Id} };
 625             }
 626         }
 627     },
 628     "MODE" => sub {
 629         my ($c, $arg, $what) = @_;
 630         return unless $c->{Ready};
 631         return unless defined($arg);
 632
 633         $what = $what || "";
 634
 635         if ($arg eq $c->{Nick}) {
 636             irc_send_num $c, 221, [], "+i";
 637         } elsif ($arg =~ /^#(.*)$/) {
 638             my $chan = $channels_by_name{$1};
 639
 640             if (defined $chan) {
 641                 if ($what eq "b") {
 642                     irc_send_num $c, 368, ["#$chan->{Name}"],
 643                         "End of channel ban list";
 644                 } else {
 645                     irc_send_num $c, 324,
 646                         ["#$chan->{Name}",
 647                          ($chan->{Type} eq "G" ? "+ip" : "+p")];
 648                     irc_send_num $c, 329,
 649                         ["#$chan->{Name}", $start_time];
 650                 }
 651             } else {
 652                 irc_send_num $c, 403, [$arg], "No such channel";
 653             }
 654         } else {
 655             irc_send_num $c, 403, [$arg], "No such channel";
 656         }
 657     },
 658     "TOPIC" => sub {
 659         my ($c, $name, $topic) = @_;
 660         return unless defined($name) && defined($topic);
 661         return unless $c->{Ready};
 662
 663         $name =~ s/^#//;
 664         my $chan = $channels_by_name{irc_lcase($name)};
 665         unless (defined($chan)) {
 666             irc_send_num $c, 401, ["#$name"], "No such nick/channel";
 667             return;
 668         }
 669
 670         my $what = $chan->{Type} eq "C" ? "channels" : "groups";
 671
 672         rtm_apicall "$what.setTopic", { channel => $chan->{Id},
 673                                         topic => $topic };
 674     },
 675     "PART" => sub {
 676         my ($c, $name) = @_;
 677         return unless $c->{Ready};
 678         return unless defined($name);
 679
 680         foreach my $n (split(/,/, $name)) {
 681             $n =~ s/^#//;
 682             my $chan = $channels_by_name{irc_lcase($n)};
 683             if (not defined($chan)) {
 684                 irc_send_num $c, 401, ["#$n"], "No such nick/channel";
 685             } elsif ($chan->{Members}->{$self_id}) {
 686                 if ($chan->{Type} eq "G") {
 687                     rtm_apicall "groups.close", { channel => $chan->{Id} };
 688                     irc_broadcast_part $self_id, $chan->{Id}
 689                       if rtm_update_part $self_id, $chan->{Id};
 690                 } else {
 691                     rtm_apicall "channels.leave", { channel => $chan->{Id} };
 692                 }
 693             }
 694         }
 695     },
 696     "LIST" => sub {
 697         my ($c, @arg) = @_;
 698         return unless $c->{Ready};
 699
 700         irc_send_num $c, 321, ["Channel"], "Users Name";
 701         foreach my $chid (keys %channels) {
 702             my $chan = $channels{$chid};
 703             my $n = keys %{$chan->{Members}};
 704
 705             irc_send_num $c, 322, ["#$chan->{Name}", $n], $chan->{Topic};
 706         }
 707         irc_send_num $c, 323, [], "End of /LIST";
 708     },
 709     "WHOIS" => sub {
 710         my ($c, $nicklist) = @_;
 711         return unless $c->{Ready};
 712         return unless defined($nicklist);
 713         my $some = 0;
 714
 715         for my $nick (split(/,/, $nicklist)) {
 716             if (irc_eq($nick, "x")) {
 717                 irc_send_num $c, 311,
 718                     ["X", "X", "localhost", "*"], "Gateway service";
 719                 irc_send_num $c, 312, ["X", "localhost"], "slirc.pl";
 720             } elsif (irc_eq($nick, $c->{Nick})) {
 721                 irc_send_whois $c, $self_id;
 722             } else {
 723                 my $user;
 724
 725                 if ($nick =~ /^.*!([^@]*)/) {
 726                     $user = $users{$1};
 727                 } else {
 728                     $user = $users_by_name{irc_lcase($nick)};
 729                     $user = undef if defined($user) && $user->{Id} eq $self_id;
 730                 }
 731
 732                 if (defined($user)) {
 733                     irc_send_whois $c, $user->{Id};
 734                 } else {
 735                     irc_send_num $c, 401, [$nick], "No such nick/channel";
 736                 }
 737             }
 738         }
 739
 740         irc_send_num $c, 318, [$nicklist], "End of /WHOIS list";
 741     },
 742     "NAMES" => sub {
 743         my ($c, $name) = @_;
 744         return unless $c->{Ready};
 745         return unless defined($name);
 746
 747         my $n = $name;
 748         $n =~ s/^#//;
 749         my $chan = $channels_by_name{irc_lcase($n)};
 750         unless (defined($chan)) {
 751             irc_send_num $c, 401, [$name], "No such nick/channel";
 752             return;
 753         }
 754
 755         irc_send_names $c, $chan;
 756     },
 757     "WHO" => sub {
 758         my ($c, $name) = @_;
 759         return unless $c->{Ready};
 760
 761         if (!defined($name)) {
 762             foreach my $u (keys %users) {
 763                 irc_send_who $c, "*", $u;
 764             }
 765             irc_send_num $c, 352, ["*", "X", "localhost", "localhost",
 766                                    "X", "H"], "0 Gateway service";
 767         } elsif (irc_eq($name, "X")) {
 768             irc_send_num $c, 352, ["*", "X", "localhost", "localhost",
 769                                    "X", "H"], "0 Gateway service";
 770         } elsif ($name =~ /^.*!([^@]*)/) {
 771             unless (exists $users{$1}) {
 772                 irc_send_num $c, 401, [$name], "No such nick/channel";
 773                 return;
 774             }
 775
 776             irc_send_who $c, $name, $1;
 777         } elsif ($name =~ /^#(.*)$/) {
 778             my $chan = $channels_by_name{irc_lcase($1)};
 779
 780             unless (defined($chan)) {
 781                 irc_send_num $c, 401, [$name], "No such nick/channel";
 782                 return;
 783             }
 784
 785             foreach my $u (keys %{$chan->{Members}}) {
 786                 irc_send_who $c, "#$chan->{Name}", $u;
 787             }
 788         } else {
 789             my $user = $users_by_name{irc_lcase($name)};
 790
 791             unless (defined($user)) {
 792                 irc_send_num $c, 401, [$name], "No such nick/channel";
 793                 return;
 794             }
 795
 796             irc_send_who $c, $name, $self_id;
 797         }
 798
 799         $name = "*" unless defined($name);
 800         irc_send_num $c, 315, [$name], "End of /WHO list";
 801     },
 802     "MOTD" => sub {
 803         my $c = shift;
 804         irc_send_motd $c;
 805     },
 806     "PRIVMSG" => sub {
 807         my ($c, $namelist, $msg) = @_;
 808         return unless $c->{Ready};
 809         return unless defined($namelist) && defined($msg);
 810
 811         $msg =~ s/&/&amp;/g;
 812         $msg =~ s/</&lt;/g;
 813         $msg =~ s/>/&gt;/g;
 814         $msg =~ s/"/&quot;/g;
 815         $msg =~ s/&lt;@([^>]+)&gt;/'<@' . irc_name_to_id($c, $1) . '>'/eg;
 816         $msg =~ s/&lt;#([^>]+)&gt;/'<#' . irc_chan_to_id($c, $1) . '>'/eg;
 817
 818         foreach my $name (split(/,/, $namelist)) {
 819             if (irc_eq($name, "X")) {
 820                 my @args = split(/  */, $msg);
 821                 my $cmd = shift @args;
 822                 my $handler = $gateway_command{lc($cmd)};
 823
 824                 if (defined $handler) {
 825                     $handler->($c, @args);
 826                 } else {
 827                     irc_gateway_notice $c, "Unknown command: $cmd";
 828                 }
 829             } elsif ($name =~ /^#(.*)$/) {
 830                 my $chan = $channels_by_name{irc_lcase($1)};
 831
 832                 if (defined $chan) {
 833                     rtm_send {
 834                         type => "message", channel => $chan->{Id},
 835                         text => $msg };
 836                 } else {
 837                     irc_send_num $c, 401, [$name], "No such nick/channel";
 838                 }
 839             } elsif (irc_eq($name, $c->{Nick})) {
 840                 rtm_send_to_user $self_id, $msg;
 841             } else {
 842                 my $user = $users_by_name{irc_lcase($name)};
 843
 844                 if (defined $user) {
 845                     rtm_send_to_user $user->{Id}, $msg;
 846                 } else {
 847                     irc_send_num $c, 401, [$name], "No such nick/channel";
 848                 }
 849             }
 850         }
 851     },
 852     "PONG" => sub {
 853         shift->{PingCount} = 0;
 854     },
 855     "QUIT" => sub {
 856         my $c = shift;
 857         irc_disconnect $c, "QUIT";
 858     },
 859 );
 860
 861 sub irc_broadcast_notice {
 862     my ($msg) = @_;
 863
 864     print "NOTICE: $msg\n";
 865     foreach my $k (keys %irc_clients) {
 866         my $c = $irc_clients{$k};
 867         irc_server_notice $c, $msg if $c->{Authed};
 868     }
 869 }
 870
 871 sub irc_id_to_name {
 872     my ($c, $id) = @_;
 873     return $c->{Nick} if $id eq $self_id;
 874     my $u = $users{$id};
 875     return $u->{Name} if defined($u);
 876     return $id;
 877 }
 878
 879 sub irc_name_to_id {
 880     my ($c, $name) = @_;
 881     return $self_id if $name eq $c->{Nick};
 882     my $u = $users_by_name{$name};
 883     return $u->{Id} if defined($u);
 884     return $name;
 885 }
 886
 887 sub irc_id_to_chan {
 888     my ($c, $id) = @_;
 889     my $ch = $channels{$id};
 890     return $ch->{Name} if defined ($ch);
 891     return $id;
 892 }
 893
 894 sub irc_chan_to_id {
 895     my ($c, $chan) = @_;
 896     my $ch = $channels_by_name{$chan};
 897     return $ch->{Id} if defined($ch);
 898     return $chan;
 899 }
 900
 901 sub irc_do_message {
 902     my ($srcid, $dstname, $subtype, $text) = @_;
 903
 904     $text =~ s/\002//g;
 905     my $prefix = "";
 906     $prefix = "\002[$subtype]\002 " if defined($subtype);
 907
 908     for my $k (keys %irc_clients) {
 909         my $c = $irc_clients{$k};
 910         next unless $c->{Ready};
 911
 912         my $translate = $text;
 913         $translate =~ s/<@([^>]+)>/'<@' . irc_id_to_name($c, $1) . '>'/eg;
 914         $translate =~ s/<#([^>]+)>/'<#' . irc_id_to_chan($c, $1) . '>'/eg;
 915         $translate =~ s/&lt;/</g;
 916         $translate =~ s/&gt;/>/g;
 917         $translate =~ s/&quot;/"/g;
 918         $translate =~ s/&amp;/&/g;
 919
 920         for my $line (split(/\n/, $translate)) {
 921             irc_send_from $c, $srcid, ["PRIVMSG", $dstname], "$prefix$line";
 922         }
 923     }
 924 }
 925
 926 sub irc_privmsg {
 927     my ($id, $subtype, $msg) = @_;
 928     irc_do_message $id, $users{$id}->{Name}, $subtype, $msg;
 929 }
 930
 931 sub irc_chanmsg {
 932     my ($id, $subtype, $chid, $msg) = @_;
 933     irc_do_message $id, "#$channels{$chid}->{Name}", $subtype, $msg;
 934 }
 935
 936 sub irc_topic_change {
 937     my ($id, $chid) = @_;
 938     my $chan = $channels{$chid};
 939
 940     foreach my $k (keys %irc_clients) {
 941         my $c = $irc_clients{$k};
 942
 943         irc_send_from $c, $id, ["TOPIC", "#$chan->{Name}"], $chan->{Topic}
 944             if $c->{Ready};
 945     }
 946 }
 947
 948 sub irc_ping {
 949     my $c = shift;
 950
 951     if (++$c->{PingCount} >= 3) {
 952         irc_disconnect $c, "Ping timeout";
 953         return;
 954     }
 955
 956     irc_send_args $c, "localhost", ["PING"], time();
 957     $c->{PingTimer} = AnyEvent->timer(after => 60, cb => sub { irc_ping($c); });
 958 }
 959
 960 sub irc_line {
 961     my ($c, $fh, $line, $eol) = @_;
 962
 963     print "IRC $fh RECV: $line\n" if $config{debug_dump};
 964
 965     utf8::decode($line);
 966
 967     my $smallargs = $line;
 968     my $bigarg = undef;
 969
 970     if ($line =~ /^(.*?) :(.*)$/) {
 971         $smallargs = $1;
 972         $bigarg = $2;
 973     }
 974
 975     my @words = split /  */, $smallargs;
 976     push @words, $bigarg if defined($bigarg);
 977
 978     if (scalar(@words)) {
 979         my $cmd = shift @words;
 980         my $handler = $irc_command{uc($cmd)};
 981
 982         $handler->($c, @words) if (defined($handler));
 983     }
 984
 985     $fh->push_read(line => sub { irc_line($c, @_) });
 986 }
 987
 988 sub irc_listen {
 989     print "Start IRC listener\n";
 990     my $listen_host = $config{unix_socket} ? "unix/" : "127.0.0.1";
 991     tcp_server $listen_host,
 992                ($config{unix_socket} || $config{port} || 6667), sub {
 993         my ($fd, $host, $port) = @_;
 994
 995         my $fh;
 996         $fh = new AnyEvent::Handle
 997           fh => $fd,
 998           on_error => sub {
 999               my ($fh, $fatal, $msg) = @_;
1000               irc_disconnect $irc_clients{$fh}, "error: $msg";
1001           },
1002           on_eof => sub {
1003               my $fh = shift;
1004               irc_disconnect $irc_clients{$fh}, "EOF";
1005           };
1006
1007         print "IRC $fh Got connection from $host:$port\n";
1008
1009         my $c = { Handle => $fh };
1010         $c->{PingTimer} = AnyEvent->timer(after => 30,
1011                 cb => sub { irc_ping $c; });
1012         $c->{PingCount} = 0;
1013         $irc_clients{$fh} = $c;
1014         $fh->push_read(line => sub { irc_line($c, @_) });
1015
1016         irc_server_notice $c, "Waiting for RTM connection" if not $connected;
1017     }, sub {
1018         chmod 0600, $config{unix_socket} if $config{unix_socket};
1019     }
1020 }
1021
1022 ########################################################################
1023 # RTM client
1024 ########################################################################
1025
1026 my $rtm_client;
1027 my $rtm_con;
1028 my $rtm_msg_id = 1;
1029 my %rtm_apicall_handles;
1030 my $rtm_cooldown_timer;
1031
1032 my %rtm_mark_queue;
1033 my $rtm_mark_timer;
1034
1035 my $rtm_ping_timer;
1036 my $rtm_ping_count;
1037
1038 sub rtm_apicall {
1039     my ($method, $args, $cb) = @_;
1040     my @encode;
1041
1042     print "RTM APICALL $method ", Dumper($args) if $config{debug_dump};
1043
1044     $args->{token} = $config{slack_token};
1045
1046     foreach my $k (keys %$args) {
1047         my $ek = uri_encode($k);
1048         my $ev = uri_encode($args->{$k});
1049
1050         push @encode, "$ek=$ev";
1051     }
1052
1053     my $x;
1054     $x = http_post "https://slack.com/api/$method", join('&', @encode),
1055         headers => {
1056             "Content-Type", "application/x-www-form-urlencoded"
1057         }, sub {
1058             my ($body, $hdr) = @_;
1059             delete $rtm_apicall_handles{$x};
1060
1061             unless ($hdr->{Status} =~ /^2/) {
1062                 irc_broadcast_notice
1063                   "API HTTP error: $method: $hdr->{Status} $hdr->{Reason}";
1064                 $cb->(undef) if defined($cb);
1065                 return;
1066             }
1067
1068             my $data = decode_json $body;
1069
1070             print "RTM REPLY $method ", Dumper($data) if $config{debug_dump};
1071
1072             unless ($data->{ok}) {
1073                 irc_broadcast_notice "API error: $data->{error}";
1074                 $cb->(undef) if defined($cb);
1075                 return;
1076             }
1077
1078             $cb->($data) if defined($cb);
1079         };
1080
1081     $rtm_apicall_handles{$x} = 1;
1082 }
1083
1084 sub rtm_send {
1085     my $frame = shift;
1086
1087     $frame->{id} = $rtm_msg_id++;
1088     print "RTM SEND: ", Dumper($frame) if $config{debug_dump};
1089     $rtm_con->send(encode_json $frame);
1090 }
1091
1092 sub rtm_update_join {
1093     my ($uid, $chid) = @_;
1094     my $chan = $channels{$chid};
1095     my $user = $users{$uid};
1096
1097     if (!$chan->{Members}->{$uid}) {
1098         $chan->{Members}->{$uid} = 1;
1099         $user->{Channels}->{$chid} = 1;
1100         return 1;
1101     }
1102
1103     return undef;
1104 }
1105
1106 sub rtm_update_part {
1107     my ($uid, $chid) = @_;
1108     my $chan = $channels{$chid};
1109     my $user = $users{$uid};
1110
1111     if ($chan->{Members}->{$uid}) {
1112         delete $channels{$chid}->{Members}->{$uid};
1113         delete $users{$uid}->{Channels}->{$chid};
1114         return 1;
1115     }
1116
1117     return undef;
1118 }
1119
1120 sub rtm_update_user {
1121     my $c = shift;
1122     my $user;
1123
1124     if (exists $users{$c->{id}}) {
1125         $user = $users{$c->{id}};
1126         my $oldname = $user->{Name};
1127         delete $users_by_name{irc_lcase($oldname)};
1128         my $newname = irc_pick_name($c->{name}, \%users_by_name);
1129
1130         $user->{Realname} = $c->{real_name} // $c->{name};
1131
1132         irc_broadcast_nick $c->{id}, $newname
1133             if $oldname ne $newname;
1134
1135         $user->{Name} = $newname;
1136         $user->{Presence} = $c->{presence} // 'active';
1137         $users_by_name{$newname} = $user;
1138     } else {
1139         my $name = irc_pick_name($c->{name}, \%users_by_name);
1140         $user = {
1141             Id => $c->{id},
1142             Name => $name,
1143             Channels => {},
1144             Realname => $c->{real_name} // $c->{name},
1145             TxQueue => [],
1146             Presence => $c->{presence} // 'active'
1147         };
1148
1149         $users{$c->{id}} = $user;
1150         $users_by_name{$name} = $user;
1151     }
1152
1153     $user->{Realname} = "" unless defined($user->{Realname});
1154 }
1155
1156 sub rtm_record_unknown_uid {
1157     my $uid = shift;
1158
1159     unless (exists $users{$uid}) {
1160         # Temporary name
1161         my $name = irc_pick_name($uid, \%users_by_name);
1162
1163         my $u = {
1164             Id => $uid,
1165             Name => $name,
1166             Channels => {},
1167             Realname => "",
1168             TxQueue => []
1169         };
1170
1171         $users{$uid} = $u;
1172         $users_by_name{irc_lcase($name)} = $u;
1173
1174         rtm_apicall "users.info", { user => $uid }, sub {
1175             my $data = shift;
1176
1177             rtm_update_user $data->{user} if defined $data;
1178         };
1179     }
1180 }
1181
1182 sub rtm_update_channel {
1183     my ($type, $c) = @_;
1184
1185     my $id = $c->{id};
1186     my $mhash = {};
1187     my $name = $c->{name};
1188
1189     $name = "+$name" if $type eq "G";
1190
1191     # Cross-reference users/channels
1192     foreach my $u (@{$c->{members}}) {
1193         rtm_record_unknown_uid $u;
1194         # Filter ourselves out of the membership list if this is a
1195         # closed group chat.
1196         next if $type eq 'G' && $u eq $self_id && !$c->{is_open};
1197         $mhash->{$u} = 1;
1198         $users{$u}->{Channels}->{$id} = 1;
1199     }
1200
1201     if (exists $channels{$id}) {
1202         my $chan = $channels{$id};
1203         $chan->{Members} = $mhash;
1204         $chan->{Topic} = $c->{topic}->{value};
1205         $chan->{Type} = $type;
1206     } else {
1207         my $name = irc_pick_name($name, \%channels_by_name);
1208         my $chan = {
1209             Id => $c->{id},
1210             Members => $mhash,
1211             Name => $name,
1212             Type => $type,
1213             Topic => $c->{topic}->{value}
1214         };
1215
1216         $channels{$c->{id}} = $chan;
1217         $channels_by_name{irc_lcase($name)} = $chan;
1218     }
1219 }
1220
1221 sub rtm_delete_channel {
1222     my $chid = shift;
1223     my $chan = $channels{$chid};
1224     return unless defined $chan;
1225
1226     foreach ($chan->{Members}) {
1227         my $user = $users{$_};
1228
1229         delete $user->{Channels}->{$chid};
1230     }
1231
1232     delete $channels_by_name{irc_lcase($chan->{Name})};
1233     delete $channels{$chid};
1234 }
1235
1236 sub rtm_mark_channel {
1237     my ($chid, $ts) = @_;
1238
1239     $rtm_mark_queue{$chid} = $ts;
1240
1241     unless (defined $rtm_mark_timer) {
1242         $rtm_mark_timer = AnyEvent->timer(after => 5, cb => sub {
1243             for my $chid (keys %rtm_mark_queue ) {
1244                 rtm_apicall "channels.mark", {
1245                     channel => $chid,
1246                     ts => $rtm_mark_queue{$chid}
1247                 };
1248             }
1249             %rtm_mark_queue = ();
1250             undef $rtm_mark_timer;
1251         });
1252     }
1253 }
1254
1255 my %rtm_command = (
1256     "presence_change" => sub {
1257         my $msg = shift;
1258         my $user = $users{$msg->{user}};
1259
1260         if (defined $user) {
1261             my $old = $user->{Presence};
1262             $user->{Presence} = $msg->{presence} if defined $user;
1263             irc_broadcast_away if
1264               $msg->{user} eq $self_id and $old ne $msg->{presence};
1265         }
1266     },
1267     "manual_presence_change" => sub {
1268         my $msg = shift;
1269         my $user = $users{$self_id};
1270         my $old = $user->{Presence};
1271
1272         $user->{Presence} = $msg->{presence};
1273         irc_broadcast_away if $old ne $msg->{presence};
1274     },
1275     "im_open" => sub {
1276         my $msg = shift;
1277         rtm_record_unknown_uid $msg->{user};
1278
1279         my $u = $users{$msg->{user}};
1280         $u->{DMId} = $msg->{channel};
1281         $users_by_dmid{$msg->{channel}} = $u;
1282
1283         foreach my $msg (@{$u->{TxQueue}}) {
1284             rtm_send { type => "message",
1285                 channel => $u->{DMId}, text => $msg };
1286         }
1287
1288         $u->{TxQueue} = [];
1289     },
1290     "im_close" => sub {
1291         my $msg = shift;
1292         my $u = $users_by_dmid{$msg->{channel}};
1293         return unless defined($u);
1294
1295         delete $u->{DMId};
1296         delete $users_by_dmid{$msg->{channel}};
1297     },
1298     "group_joined" => sub {
1299         my $msg = shift;
1300
1301         rtm_update_channel "G", $msg->{channel};
1302         irc_broadcast_join $self_id, $msg->{channel}->{id};
1303     },
1304     "group_left" => sub {
1305         my $msg = shift;
1306
1307         irc_broadcast_part $self_id, $msg->{channel}
1308           if rtm_update_part $self_id, $msg->{channel};
1309     },
1310     "group_archive" => sub {
1311         my $msg = shift;
1312
1313         irc_broadcast_part $self_id, $msg->{channel}
1314           if rtm_update_part $self_id, $msg->{channel};
1315         rtm_delete_channel $msg->{channel};
1316     },
1317     "channel_joined" => sub {
1318         my $msg = shift;
1319
1320         rtm_update_channel "C", $msg->{channel};
1321         irc_broadcast_join $self_id, $msg->{channel}->{id};
1322     },
1323     "channel_left" => sub {
1324         my $msg = shift;
1325
1326         irc_broadcast_part $self_id, $msg->{channel}
1327           if rtm_update_part $self_id, $msg->{channel};
1328     },
1329     "channel_archive" => sub {
1330         my $msg = shift;
1331
1332         irc_broadcast_part $self_id, $msg->{channel}
1333           if rtm_update_part $self_id, $msg->{channel};
1334         rtm_delete_channel $msg->{channel};
1335     },
1336     "member_joined_channel" => sub {
1337         my $msg = shift;
1338
1339         rtm_record_unknown_uid $msg->{user};
1340         irc_broadcast_join $msg->{user}, $msg->{channel}
1341           if rtm_update_join($msg->{user}, $msg->{channel});
1342     },
1343     "member_left_channel" => sub {
1344         my $msg = shift;
1345
1346         irc_broadcast_part $msg->{user}, $msg->{channel}
1347           if rtm_update_part($msg->{user}, $msg->{channel});
1348     },
1349     "pong" => sub {
1350         $rtm_ping_count = 0;
1351     },
1352     "message" => sub {
1353         my $msg = shift;
1354         my $chan = $channels{$msg->{channel}};
1355         my $subtype = $msg->{subtype} || "";
1356         my $uid = $msg->{user} || $msg->{comment}->{user} || $msg->{bot_id};
1357         my $text = $msg->{text} // '';
1358
1359         if (defined($msg->{attachments})) {
1360             my $attext = join '\n', map {
1361                 ($_->{title} or "")
1362                   . " " . ($_->{text} or "")
1363                   . " " . ($_->{title_link} or "") } @{$msg->{attachments}};
1364             $text .= "\n" unless length($text);
1365             $text .= $attext;
1366         }
1367
1368         if (defined($chan)) {
1369             if ($subtype eq "channel_topic" or $subtype eq "group_topic") {
1370                 $chan->{Topic} = $msg->{topic};
1371                 irc_topic_change $uid, $chan->{Id};
1372             } else {
1373                 irc_chanmsg $uid, $msg->{subtype}, $chan->{Id}, $text;
1374             }
1375             rtm_mark_channel $chan->{Id}, $msg->{ts};
1376         } else {
1377             irc_privmsg $uid, $msg->{subtype}, $text;
1378         }
1379
1380         if ($subtype eq "file_share") {
1381             my $fid = $msg->{file}->{id};
1382             rtm_apicall "files.info", { file => $fid }, sub {
1383                 my $data = shift;
1384                 return unless defined $data;
1385
1386                 my $body = $data->{content};
1387                 return unless length($body) <= 65536;
1388
1389                 if (defined $chan) {
1390                     irc_chanmsg $uid, ">$fid", $chan->{Id}, $body;
1391                 } else {
1392                     irc_privmsg $uid, ">$fid", $body;
1393                 }
1394             };
1395         }
1396     },
1397 );
1398
1399 sub rtm_send_to_user {
1400     my ($id, $msg) = @_;
1401     my $u = $users{$id};
1402
1403     if (defined($u->{DMId}) && length($u->{DMId})) {
1404         rtm_send { type => "message",
1405                 channel => $u->{DMId}, text => $msg };
1406         return;
1407     }
1408
1409     push @{$u->{TxQueue}}, $msg;
1410
1411     if (!defined($u->{DMId})) {
1412         rtm_apicall "im.open", { user => $u->{Id} }, sub {
1413             my $result = shift;
1414             unless (defined $result) {
1415                 delete $u->{DMId};
1416                 foreach my $m (@{$u->{TxQueue}}) {
1417                     irc_broadcast_notice "Failed to send to $u->{Name}: $m";
1418                 }
1419                 $u->{TxQueue} = [];
1420             }
1421         };
1422
1423         $u->{DMId} = "";
1424     }
1425 }
1426
1427 sub rtm_start;
1428
1429 sub rtm_cooldown {
1430     return if defined($rtm_cooldown_timer);
1431     print "Waiting before reinitiating RTM\n";
1432     $rtm_cooldown_timer = AnyEvent->timer(after => 5, cb => sub {
1433         undef $rtm_cooldown_timer;
1434         rtm_start;
1435     });
1436 };
1437
1438 sub rtm_destroy {
1439     my $msg = shift;
1440     return unless defined($rtm_con);
1441
1442     irc_broadcast_notice $msg;
1443
1444     $connected = 0;
1445     undef $self_id;
1446     %channels = ();
1447     %channels_by_name = ();
1448     %users = ();
1449     %users_by_name = ();
1450     %users_by_dmid = ();
1451
1452     %rtm_apicall_handles = (); # cancel outstanding requests
1453     %rtm_mark_queue = ();
1454     undef $rtm_mark_timer;
1455     undef $rtm_ping_timer;
1456     $rtm_con->close;
1457     undef $rtm_con;
1458     undef $rtm_client;
1459
1460     irc_disconnect_all;
1461     rtm_cooldown;
1462 }
1463
1464 sub rtm_ping {
1465     if (++$rtm_ping_count >= 2) {
1466         rtm_destroy "RTM ping timeout";
1467         return;
1468     }
1469
1470     rtm_send { type => "ping" };
1471     $rtm_ping_timer = AnyEvent->timer(after => 60, cb => \&rtm_ping);
1472 }
1473
1474 sub rtm_start_ws {
1475     my $url = shift;
1476
1477     return if defined($rtm_client);
1478     $rtm_client = AnyEvent::WebSocket::Client->new;
1479
1480     print "WSS URL: $url\n" if $config{debug_dump};
1481     $rtm_client->connect($url)->cb(sub {
1482         $rtm_con = eval { shift->recv; };
1483         if ($@) {
1484             irc_broadcast_notice "WSS connection failed: $@\n";
1485             undef $rtm_client;
1486             rtm_cooldown;
1487         }
1488
1489         print "WSS connected\n";
1490         $rtm_msg_id = 1;
1491         $rtm_ping_count = 0;
1492         $connected = 1;
1493         irc_check_welcome_all;
1494
1495         $rtm_ping_timer = AnyEvent->timer(after => 60, cb => \&rtm_ping);
1496
1497         $rtm_con->on(each_message => sub {
1498             eval {
1499                 shift;
1500                 my $msg = decode_json shift->{body};
1501
1502                 print "RTM RECV: ", Dumper($msg) if $config{debug_dump};
1503                 irc_broadcast_notice "RTM error: $msg->{error}->{msg}"
1504                     if $msg->{error};
1505
1506                 if (defined $msg->{type}) {
1507                     my $handler = $rtm_command{$msg->{type}};
1508                     $handler->($msg) if defined($handler);
1509                 }
1510             };
1511             print "Error in message handler: $@" if $@;
1512         });
1513
1514         $rtm_con->on(finish => sub {
1515             eval {
1516                 my ($con) = @_;
1517
1518                 if (defined $con->close_error) {
1519                     rtm_destroy "RTM connection error: $con->close_error";
1520                 } elsif (defined $con->close_reason) {
1521                     rtm_destroy "RTM connection closed: $con->close_reason";
1522                 } else {
1523                     rtm_destroy "RTM connection finished";
1524                 }
1525             };
1526             print "Error in finish handler: $@" if $@;
1527         });
1528     });
1529 };
1530
1531 sub rtm_start {
1532     print "Requesting RTM connection\n";
1533     rtm_apicall "rtm.start", {}, sub {
1534         my $data = shift;
1535
1536         unless (defined($data)) {
1537             rtm_cooldown;
1538             return;
1539         }
1540
1541         $self_id = $data->{self}->{id};
1542
1543         foreach my $c (@{$data->{users}}) {
1544             rtm_update_user $c;
1545         }
1546
1547         foreach my $c (@{$data->{ims}}) {
1548             my $u = $users{$c->{user}};
1549
1550             $u->{DMId} = $c->{id};
1551             $users_by_dmid{$c->{id}} = $u;
1552         }
1553
1554         foreach my $c (@{$data->{channels}}) {
1555             rtm_update_channel "C", $c unless $c->{is_archived};
1556         }
1557
1558         foreach my $c (@{$data->{bots}}) {
1559             rtm_update_user $c;
1560             my $n = $c->{id};
1561         }
1562
1563         foreach my $c (@{$data->{groups}}) {
1564             rtm_update_channel "G", $c unless $c->{is_archived};
1565         }
1566
1567         rtm_start_ws $data->{url};
1568     };
1569 };
1570
1571 ########################################################################
1572 # RTM kick-off
1573 ########################################################################
1574
1575 my $cfgfile = shift || die "You must specify a config file";
1576 open(my $cfg, $cfgfile) || die "Can't open $cfgfile";
1577 foreach (<$cfg>) {
1578     chomp;
1579     $config{$1} = $2 if /^([-_0-9a-zA-Z]+)=(.*)$/;
1580 }
1581 close($cfg);
1582
1583 rtm_start;
1584 irc_listen;
1585 AnyEvent->condvar->recv;