machine.asm

   1 ;;; This file define/describes the "machine"
   2 ;;;
   3 ;;; Abstract Machine:
   4 ;;; https://en.wikibooks.org/wiki/X86_Assembly/X86_Architecture
   5 ;;;
   6 ;;; General Purpose Registers ( * marks those used in syscalls )
   7 ;;;  *rax = ( -, eax = ( -, ax = ( ah, al) )) "accumulator"
   8 ;;;   rbx = ( -, ebx = ( -, bx = ( bh, bl) )) "base"
   9 ;;;  *rcx = ( -, ecx = ( -, cx = ( ch, cl) )) "counter"
  10 ;;;  *rdx = ( -, edx = ( -, dx = ( dh, dl) )) "data"
  11 ;;;   rsp = ( -, esp = ( -, sp = ( -, spl) )) "stack pointer"
  12 ;;;   rbp = ( -, ebp = ( -, bp = ( -, bpl) )) "stack base pointer"
  13 ;;;  *rsi = ( -, esi = ( -, si = ( -, sil) )) "source"
  14 ;;;  *rdi = ( -, edi = ( -, di = ( -, dil) )) "destination"
  15 ;;;  *r8
  16 ;;;  *r9
  17 ;;;   r10
  18 ;;;  *r11
  19 ;;;   r12
  20 ;;;   r13
  21 ;;;   r14
  22 ;;;   r15
  23 ;;; clobbers rdi rsi rdx rcx r8 r9 r11
  24 ;;; rax = syscall id
  25 ;;;
  26 ;;; Segment Registers
  27 ;;;   SS "Stack Segment"
  28 ;;;   CS "Code Segment"
  29 ;;;   DS "Data Segment"
  30 ;;;   ES "Extra Segment"
  31 ;;;   FS "more Extra Segment"
  32 ;;;   GS "more more Extra Segment"
  33 ;;;
  34 ;;; EFLAGS Register
  35 ;;;   0,0,0,0,0,0,0,0,0,0,ID,VIP,VIF,AC,VM,RF,
  36 ;;;   0,NT,[IOPL,IOPL],OF,DF,IF,TF,SF,ZF,0,AF,0,PF,1,CF
  37 ;;;
  38 ;;; Instruction pointer
  39 ;;;   EIP
  40 ;;;
  41 ;;; Syscall allocations
  42 ;;; clobbers rdi rsi rdx rcx r8 r9 r11
  43 ;;; rax = syscall id
  44 ;;;
  45
  46 ;;; ######################################################################
  47
  48 ;;; ============================================================
  49 ;;; FORTH machine model
  50 ;;; rsp = data stack pointer
  51 ;;; rbp = return stack pointer
  52 ;;; rsi = instruction pointer
  53
  54 ;;; ========================================
  55 ;;; The pushr macro pushes x onto the return stack
  56 ;;; The popr macro pops x from the return stack
  57 macro pushr x {
  58         sub rbp, 8
  59         mov [rbp], x
  60 }
  61
  62 macro popr x {
  63         mov x, [rbp]
  64         add rbp, 8
  65 }
  66
  67 ;;; ========================================
  68 ;;; The next macro "moves" execution to the next FORTH instruction,
  69 ;;; using rsi as instruction pointer. It points to the doer field of a
  70 ;;; word, which points to the assembly code that implements the
  71 ;;; execution effect of the word. That doer code is entered with rsi
  72 ;;; referring to the subsequent address in the colling word, and rax
  73 ;;; referring to the doer field of the called word.
  74
  75 macro next {
  76         lodsq                   ; mov rax, [rsi] + add rsi,8
  77         jmp qword [rax]         ; goto code of that FORTH word (64 bit jump)
  78 }
  79
  80 ;;; ========================================
  81 ;;; The FORTH macro transitions to inline FORTH execution.
  82 macro FORTH {
  83         local forthcode
  84         mov rsi,forthcode
  85         next
  86         ;; align 8
  87 forthcode:
  88 }
  89
  90 ;;; ========================================
  91 ;;; The ENDFORTH macro transitions back to inline assembler after FORTH
  92
  93 macro ENDFORTH {
  94         dq inline_code
  95 }
  96
  97 ;;; ========================================
  98 ;;; The DOFORTH lays out a single FORTH call
  99
 100 macro DOFORTH label {
 101         FORTH
 102         dq label
 103         ENDFORTH
 104 }
 105
 106         previous_word = 0       ; Used for chaining the words
 107
 108         IMMEDIATE = 1           ; optional flag (symbol)
 109
 110 ;;; ========================================
 111 ;;; Macro WORD starts a FORTH word definition in this code.
 112 ;;; The layout of a word is as follows:
 113 ;;; TFA: [8 bytes] pointer to previous word in the word list
 114 ;;;      [8 bytes] pointer to the word's CFA
 115 ;;;      [8 bytes] a flags field
 116 ;;;      [8 bytes] the length of the word's pname
 117 ;;;      [varying] the word's pname
 118 ;;;      [1 byte]  NUL -- making an asciiz of the pname
 119 ;;;      ;;[? bytes] 0-7 bytes for address alignment to [disabled]
 120 ;;;      [8 bytes] pointer to the word's TFA
 121 ;;; OFF: [8 bytes] the DOES offset for the word
 122 ;;; CFA: [8 bytes] pointer to the word's "doer" code
 123 ;;; DFA: [? bytes] the word's data field
 124
 125 macro WORD label, name, doer, flags, previous, offset {
 126         local pname
 127         ;; align 8
 128 label#_TFA:
 129         ;; TFA
 130         if previous eq
 131             dq previous_word
 132         else
 133             dq previous
 134         end if
 135         previous_word = label#_TFA
 136         ;; PFA
 137 label#_pCFA:
 138         dq label#_CFA           ; link to CFA of word
 139         dq flags + 0
 140 label#_PFA:
 141         dq pname - $ - 8
 142         db name
 143 pname:  db 0                    ; extra NUL byte
 144         ;; align 8
 145 label#_pTFA:
 146         dq label#_TFA           ; link to TFA of word
 147 label#_OFF:
 148         dq offset + 0           ; The DOES offset. Defaults to 0.
 149         ;; also CFA = pointer to "doer"
 150 label#_CFA:
 151 label:
 152         if doer eq
 153             dq doforth
 154         else
 155             if doer in <fasm>
 156                 dq dofasm ; label#_DFA
 157             else
 158                 dq doer
 159             end if
 160         end if
 161         ;; DFA
 162 label#_DFA:
 163 }
 164
 165 macro tfa2cfa reg {
 166         mov reg,qword [reg+8]
 167 }
 168 macro tfa2does reg {
 169         tfa2cfa reg
 170         sub reg,8
 171 }
 172 macro tfa2dfa reg {
 173         tfa2cfa reg
 174         add reg,8
 175 }
 176 macro tfa2flags reg {
 177         add reg,16
 178 }
 179 macro tfa2pfa reg {
 180         add reg,24
 181 }
 182 macro tfa2pname reg {
 183         add reg,32
 184 }
 185 macro cfa2tfa reg {
 186         sub reg,16
 187         mov reg,qword [reg]
 188 }
 189 macro cfa2dfa reg {
 190         add reg,8
 191 }
 192 macro dfa2cfa reg {
 193         sub reg,8
 194 }
 195 macro dfa2tfa reg {
 196         sub reg,24
 197         mov reg,qword [reg]
 198 }
 199 macro pushpname rg {    ; ( reg -- chars* length )
 200         add rg,8
 201         push rg
 202         sub rg,8
 203         push qword [rg]
 204 }
 205 ;;; ========================================
 206 ;;; The BLOCK macro lays out the length for a subsequent block to the
 207 ;;; given label.
 208 macro BLOCK endlabel {
 209         local datastart
 210         dq endlabel - datastart
 211 datastart:
 212         }
 213
 214 ;;; ========================================
 215 ;;; The STRING macro lays out length cell and data for several string
 216 ;;; components.
 217 macro STRING [data] {
 218 common
 219         local datastart, dataend
 220         dq dataend - datastart
 221 datastart:
 222 forward
 223         db data
 224 common
 225 dataend:
 226         }
 227
 228 ;;; ========================================
 229 ;;; The BRANCH macro lays out FORTH words BRANCH and 0BRANCH with offset
 230 macro BRANCH zero,label {
 231         if zero in <0>
 232             dq p_zero_branch
 233         else
 234             dq p_zero_branch
 235         end if
 236         dq label - $ - 8
 237 }