CMakeModules/CodeCoverage.cmake

   1 # Copyright (c) 2012 - 2015, Lars Bilke
   2 # All rights reserved.
   3 #
   4 # Redistribution and use in source and binary forms, with or without modification,
   5 # are permitted provided that the following conditions are met:
   6 #
   7 # 1. Redistributions of source code must retain the above copyright notice, this
   8 #    list of conditions and the following disclaimer.
   9 #
  10 # 2. Redistributions in binary form must reproduce the above copyright notice,
  11 #    this list of conditions and the following disclaimer in the documentation
  12 #    and/or other materials provided with the distribution.
  13 #
  14 # 3. Neither the name of the copyright holder nor the names of its contributors
  15 #    may be used to endorse or promote products derived from this software without
  16 #    specific prior written permission.
  17 #
  18 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
  19 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  20 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  21 # DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR
  22 # ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  23 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  24 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON
  25 # ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  26 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  27 # SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  28 #
  29 #
  30 #
  31 # 2012-01-31, Lars Bilke
  32 # - Enable Code Coverage
  33 #
  34 # 2013-09-17, Joakim Söderberg
  35 # - Added support for Clang.
  36 # - Some additional usage instructions.
  37 #
  38 # 2016-10-31, Felipe Barriga Richards
  39 # - Remove C++ support
  40 #
  41 # USAGE:
  42
  43 # 0. (Mac only) If you use Xcode 5.1 make sure to patch geninfo as described here:
  44 #      http://stackoverflow.com/a/22404544/80480
  45 #
  46 # 1. Copy this file into your cmake modules path.
  47 #
  48 # 2. Add the following line to your CMakeLists.txt:
  49 #      INCLUDE(CodeCoverage)
  50 #
  51 # 3. Set compiler flags to turn off optimization and enable coverage:
  52 #    SET(CMAKE_CXX_FLAGS "-g -O0 -fprofile-arcs -ftest-coverage")
  53 #        SET(CMAKE_C_FLAGS "-g -O0 -fprofile-arcs -ftest-coverage")
  54 #
  55 # 3. Use the function SETUP_TARGET_FOR_COVERAGE to create a custom make target
  56 #    which runs your test executable and produces a lcov code coverage report:
  57 #    Example:
  58 #        SETUP_TARGET_FOR_COVERAGE(
  59 #                               my_coverage_target  # Name for custom target.
  60 #                               test_driver         # Name of the test driver executable that runs the tests.
  61 #                                                                       # NOTE! This should always have a ZERO as exit code
  62 #                                                                       # otherwise the coverage generation will not complete.
  63 #                               coverage            # Name of output directory.
  64 #                               )
  65 #
  66 # 4. Build a Debug build:
  67 #        cmake -DCMAKE_BUILD_TYPE=Debug ..
  68 #        make
  69 #        make my_coverage_target
  70 #
  71 #
  72
  73 # Check prereqs
  74 FIND_PROGRAM( GCOV_PATH gcov )
  75 FIND_PROGRAM( LCOV_PATH lcov )
  76 FIND_PROGRAM( GENHTML_PATH genhtml )
  77 FIND_PROGRAM( GCOVR_PATH gcovr PATHS ${CMAKE_SOURCE_DIR}/tests)
  78
  79 IF(NOT GCOV_PATH)
  80         MESSAGE(FATAL_ERROR "gcov not found! Aborting...")
  81 ENDIF() # NOT GCOV_PATH
  82
  83 IF("${CMAKE_CXX_COMPILER_ID}" MATCHES "(Apple)?[Cc]lang")
  84         IF("${CMAKE_CXX_COMPILER_VERSION}" VERSION_LESS 3)
  85                 MESSAGE(FATAL_ERROR "Clang version must be 3.0.0 or greater! Aborting...")
  86         ENDIF()
  87 ELSEIF(NOT CMAKE_COMPILER_IS_GNUCC)
  88         MESSAGE(FATAL_ERROR "Compiler is not GNU gcc! Aborting...")
  89 ENDIF() # CHECK VALID COMPILER
  90
  91 SET(CMAKE_C_FLAGS_COVERAGE
  92     "-g -O0 --coverage -fprofile-arcs -ftest-coverage"
  93     CACHE STRING "Flags used by the C compiler during coverage builds."
  94     FORCE )
  95 SET(CMAKE_EXE_LINKER_FLAGS_COVERAGE
  96     ""
  97     CACHE STRING "Flags used for linking binaries during coverage builds."
  98     FORCE )
  99 SET(CMAKE_SHARED_LINKER_FLAGS_COVERAGE
 100     ""
 101     CACHE STRING "Flags used by the shared libraries linker during coverage builds."
 102     FORCE )
 103 MARK_AS_ADVANCED(
 104     CMAKE_C_FLAGS_COVERAGE
 105     CMAKE_EXE_LINKER_FLAGS_COVERAGE
 106     CMAKE_SHARED_LINKER_FLAGS_COVERAGE )
 107
 108 IF ( NOT (CMAKE_BUILD_TYPE STREQUAL "Debug" OR CMAKE_BUILD_TYPE STREQUAL "Coverage"))
 109   MESSAGE( WARNING "Code coverage results with an optimized (non-Debug) build may be misleading" )
 110 ENDIF() # NOT CMAKE_BUILD_TYPE STREQUAL "Debug"
 111
 112
 113 # Param _targetname     The name of new the custom make target
 114 # Param _testrunner     The name of the target which runs the tests.
 115 #                                               MUST return ZERO always, even on errors.
 116 #                                               If not, no coverage report will be created!
 117 # Param _outputname     lcov output is generated as _outputname.info
 118 #                       HTML report is generated in _outputname/index.html
 119 # Optional fourth parameter is passed as arguments to _testrunner
 120 #   Pass them in list form, e.g.: "-j;2" for -j 2
 121 FUNCTION(SETUP_TARGET_FOR_COVERAGE _targetname _testrunner _outputname)
 122
 123         IF(NOT GCOV_PATH)
 124                 MESSAGE(FATAL_ERROR "gcov not found! Aborting...")
 125         ENDIF() # NOT LCOV_PATH
 126
 127         IF(NOT LCOV_PATH)
 128                 MESSAGE(FATAL_ERROR "lcov not found! Aborting...")
 129         ENDIF() # NOT LCOV_PATH
 130
 131         IF(NOT GENHTML_PATH)
 132                 MESSAGE(FATAL_ERROR "genhtml not found! Aborting...")
 133         ENDIF() # NOT GENHTML_PATH
 134
 135         SET(coverage_info "${CMAKE_BINARY_DIR}/${_outputname}.info")
 136         SET(coverage_cleaned "${coverage_info}.cleaned")
 137
 138         SEPARATE_ARGUMENTS(test_command UNIX_COMMAND "${_testrunner}")
 139
 140         # Setup target
 141         ADD_CUSTOM_TARGET(${_targetname}
 142
 143                 # Cleanup lcov
 144                 ${LCOV_PATH} --directory . --zerocounters
 145
 146                 # Run tests
 147                 COMMAND ${test_command} ${ARGV3}
 148
 149                 # Capturing lcov counters and generating report
 150                 COMMAND ${LCOV_PATH} --directory . --capture --output-file ${coverage_info}
 151                 COMMAND ${LCOV_PATH} --remove ${coverage_info} 'tests/*' '/usr/*' --output-file ${coverage_cleaned}
 152                 COMMAND ${GENHTML_PATH} -o ${_outputname} ${coverage_cleaned}
 153                 COMMAND ${CMAKE_COMMAND} -E remove ${coverage_info} ${coverage_cleaned}
 154
 155                 WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 156                 COMMENT "Resetting code coverage counters to zero.\nProcessing code coverage counters and generating report."
 157         )
 158
 159         # Show info where to find the report
 160         ADD_CUSTOM_COMMAND(TARGET ${_targetname} POST_BUILD
 161                 COMMAND ;
 162                 COMMENT "Open ./${_outputname}/index.html in your browser to view the coverage report."
 163         )
 164
 165 ENDFUNCTION() # SETUP_TARGET_FOR_COVERAGE
 166
 167 # Param _targetname     The name of new the custom make target
 168 # Param _testrunner     The name of the target which runs the tests
 169 # Param _outputname     cobertura output is generated as _outputname.xml
 170 # Optional fourth parameter is passed as arguments to _testrunner
 171 #   Pass them in list form, e.g.: "-j;2" for -j 2
 172 FUNCTION(SETUP_TARGET_FOR_COVERAGE_COBERTURA _targetname _testrunner _outputname)
 173
 174         IF(NOT PYTHON_EXECUTABLE)
 175                 MESSAGE(FATAL_ERROR "Python not found! Aborting...")
 176         ENDIF() # NOT PYTHON_EXECUTABLE
 177
 178         IF(NOT GCOVR_PATH)
 179                 MESSAGE(FATAL_ERROR "gcovr not found! Aborting...")
 180         ENDIF() # NOT GCOVR_PATH
 181
 182         ADD_CUSTOM_TARGET(${_targetname}
 183
 184                 # Run tests
 185                 ${_testrunner} ${ARGV3}
 186
 187                 # Running gcovr
 188                 COMMAND ${GCOVR_PATH} -x -r ${CMAKE_SOURCE_DIR} -e '${CMAKE_SOURCE_DIR}/tests/'  -o ${_outputname}.xml
 189                 WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 190                 COMMENT "Running gcovr to produce Cobertura code coverage report."
 191         )
 192
 193         # Show info where to find the report
 194         ADD_CUSTOM_COMMAND(TARGET ${_targetname} POST_BUILD
 195                 COMMAND ;
 196                 COMMENT "Cobertura code coverage report saved in ${_outputname}.xml."
 197         )
 198
 199 ENDFUNCTION() # SETUP_TARGET_FOR_COVERAGE_COBERTURA